在pascal中动态分配匿名函数

Question

我希望能够在pascal中动态生成弹出菜单.

我还希望能够为每个菜单项动态分配OnClick处理程序.

这是我习惯于在C#中做的事情,这是我在pascal中的尝试.

菜单项onClick事件处理程序需要属于一个对象(of Object),所以我为此创建一个容器对象.

这是我的代码:

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Vcl.Menus;

type
  TForm1 = class(TForm)
    PopupMenu1: TPopupMenu;
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

  TFoo = class
    public
      Bar : String;
      Val : Integer;
  end;

  TNotifyEventWrapper = class
    private
      FProc: TProc<TObject>;
      I : Integer;
    public
      constructor Create(Proc: TProc<TObject>);
    published
      procedure Event(Sender: TObject);
  end;

var
  Form1: TForm1;
  NE : TNotifyEventWrapper;

implementation

{$R *.dfm}

constructor TNotifyEventWrapper.Create(Proc: TProc<TObject>);
begin
    inherited Create;
    FProc := Proc;
end;

procedure TNotifyEventWrapper.Event(Sender: TObject);
begin
    ShowMessage(IntToStr(I));
    FProc(Sender);
end;

procedure TForm1.FormCreate(Sender: TObject);
var
    F : TFoo;
    I: Integer;
    mi : TMenuItem;
begin
    if Assigned(NE) then FreeAndNil(NE);

    for I := 1 to 10 do
    begin
        F := TFoo.Create;
        F.Bar := 'Hello World!';
        F.Val := I;
        NE := TNotifyEventWrapper.Create
        (
            procedure (Sender :TObject)
            begin
               ShowMessage(F.Bar + ' ' + inttostr(F.Val) + Format('  Addr = %p', [Pointer(F)]) + Format('Sender = %p, MI.OnClick = %p', [Pointer(Sender), Pointer(@TMenuItem(Sender).OnClick)]));
            end
        );
        NE.I := I;

        mi := TMenuItem.Create(PopupMenu1);

        mi.OnClick := NE.Event;

        mi.Caption := inttostr(F.Val);

        PopupMenu1.Items.Add(mi);
    end;
end;

end.

单击菜单项目编号6

该程序显示预期的消息

但是,下一条消息未显示预期结果.

而不是6它显示项目10

无论我点击列表中的哪个项目,它们似乎都会触发列表中最后一项的事件处理程序(10).

有人向我建议,NE对象的成员过程Event与该对象的所有实例的内存地址相同.

无论我点击哪个菜单项,内存地址MI.OnClick都是相同的.

Answer 1

理解这一点的关键是要理解变量捕获捕获变量而不是值.

你的匿名方法都捕获相同的变量F.该变量只有一个实例,因为FormCreate只执行一次.这解释了这种行为.当你的anon方法执行变量F时,在最后的循环迭代中赋值给它.

您需要的是每个不同的anon方法捕获不同的变量.您可以通过在生成每个不同的anon方法时创建新的堆栈帧来完成此操作.

function GetWrapper(F: Foo): TNotifyEventWrapper;
begin
  Result := TNotifyEventWrapper.Create(
    procedure(Sender: TObject)
    begin
      ShowMessage(F.Bar + ...);
    end
  );
end;

因为函数的参数GetWrapper是该函数的堆栈帧中的局部变量,所以每次调用GetWrapper都会创建该局部变量的新实例.

你可以放在GetWrapper你喜欢的地方.作为嵌套函数FormCreate,或作为私有方法,或在单元范围内.

然后像这样构建菜单:

F := TFoo.Create;
F.Bar := 'Hello World!';
F.Val := I;
NE := GetWrapper(F);
NE.I := I;

相关阅读:

• http://docwiki.embarcadero.com/RADStudio/en/Anonymous_Methods_in_Delphi#Variable_Binding_Mechanism
• 匿名方法 - 变量捕获与值捕获
• http://blogs.embarcadero.com/abauer/2008/10/15/38876