ColdFusion和PHP之间的有效/无效电子邮件格式策略差异

Question

我既不是在PHP和ColdFusion之间进行战争,也不是要找出哪种语言比其他语言更好.所以请为这一点提供合理的论据.

我也不确定这类问题是否适合stackoverflow的策略.但在这里

如果您在ColdFusion中验证电子邮件地址test @ testdomain,它会说它是有效的电子邮件地址.但如果您在PHP中测试电子邮件地址,则说它是无效的电子邮件地址.

根据维基百科,这是有效的电子邮件地址.请搜索术语admin @ mailserver1(没有TLD的本地域名)

我的问题是,为什么实施及其背后的原因存在差异.

ColdFusion代码

<cfdump var="#isValid("email","test@testdomain")#">

产量

Yes

PHP代码

<?php
$email = "test@testdomain";
if (!filter_var($email, FILTER_VALIDATE_EMAIL)) {
  $emailErr = "Invalid"; 
}
else
{
 $emailErr = "valid";
}

echo $emailErr; 
?>

产量

Invalid

Answer 1

创建您自己的包装器。我的 isEmail() UDF 使用特殊规则根据 IP 包含/排除测试电子邮件地址。（我必须允许一些特定的 IP 进行测试。）我还添加了第二个参数来指示验证类型... ColdFusion 的 BIF isValid("email") 是默认值，然后是正则表达式、Java w/DNS（尊重 DNS） TTL）和没有 DNS 的 Java。

这是来自 CFLib.org 的正则表达式 UDF：

http://www.cflib.org/udf/isEmail

function isEmail(str) {
    return (REFindNoCase("^['_a-z0-9-\+]+(\.['_a-z0-9-\+]+)*@[a-z0-9-]+(\.[a-z0-9-]+)*\.(([a-z]{2,3})|(aero|asia|biz|cat|coop|info|museum|name|jobs|post|pro|tel|travel|mobi))$",
arguments.str) AND len(listGetAt(arguments.str, 1, "@")) LTE 64 AND
len(listGetAt(arguments.str, 2, "@")) LTE 255) IS 1;
}

我更喜欢使用 Java，因为它具有更多功能、更好的故障消息、可以选择使用 DNS（用于 TLD 验证和 MX 记录检查）并且可以安装在 ColdFusion 8-11 上。（我发现当前支持的 ColdFusion 版本中报告的错误仅在最新或即将推出的版本中得到修复。）

有一个 PHP 版本的 java 类可用。通过使用此功能，ColdFusion、PHP 和 C# 结果将保持一致。

https://code.google.com/p/isemail/downloads/list

如果您想尝试使用 ColdFusion 进行 Java 实现，请查看：

http://isemail.info/

这是我在这里发布的一些示例代码：

http://gamesover2600.tumblr.com/post/93979011009/better-coldfusion-email-validation-using-java

<cfscript>
/* Copy IsEMail.jar to java path. Download from https://code.google.com/p/isemail/downloads/list */
emails = ["test@test.com",
    "valid_but_no_mx@fake-domain.com",
    "valid_but_no_dns@fake-domain2.com",
    """much.more unusual""@example.com",
    "john.smith@example.com(comment)",
    """first\last""@iana.org",
    "first.last@com",
    """Joe.\Blow""@iana.org",
    "foobar@192.168.0.1",
    "first.last@-xample.com",
    "first.last@exampl-.com",
    "first.last@x234567890123456789012345678901234567890123456789012345678901234.iana.org"];

/* Set DNS server to prevent ColdFusion error:
   javax.naming.ConfigurationException: localhost:2932 is not a valid DNS pseudo-URL */
sys = createObject("java", "java.lang.System");
sys.setProperty("java.naming.provider.url","dns:/YOUR_DNS_SERVER");

isEmailObj = CreateObject("java", "com.dominicsayers.isemail.IsEMail");
check_DNS = true;
responseLabels = ListToArray("Email,isValid,Status,Rule ID,Rule Name,SMTP SMTP Code");

function checkEmail(e, useDNS){
    var check = isEmailObj.is_email_verbose(e, Check_DNS);
    var response =  structNew();
    response["Email"] = e;
    response["isValid"] = check.getState().isValid();
    response["Status"] = check.getStatusTextExplanatory();
    response["Rule ID"] = check.getId();
    response["Rule Name"] = check.getConstantName();
    response["SMTP"] = "N/A";
    response["SMTP Code"] = "N/A";
    if (useDNS){
        response["SMTP"] = check.getSmtpCode();
        response["SMTP Code"] = check.getSmtpCodeText();
    }
    return response;
}

for(i=1; i LTE ArrayLen(emails); i=i+1){
    writeoutput('<h2>#emails[i]#</h2>');
    temp = checkEmail(emails[i], check_DNS);
    for(a=1; a LTE ArrayLen(responseLabels); a=a+1){
        if (StructKeyExists(temp, responseLabels[a])){
            writeoutput('<div><b>#responseLabels[a]#:</b> #Temp[responseLabels[a]]#</div>');
        }
    }
    writeoutput('<hr>');
}
</cfscript>