设置/ p循环？

Question

这大概是不可能的,但我有,通过使用显示动画徽标循环TYPE输入logo_(framenumber).txt和framenumber通过循环确定:

:s
if %m%==379 set m=0
cls
TYPE Logo_%m%.txt
set /a m=%m%+1
goto s

我希望能够使用set /p选项并且不会干扰/停止循环,以便在用户输入设置/p输入时播放动画.我认为有一种方法可以做到,FOR但我不知道如何.有任何想法吗？谢谢.

Answer 1

虽然这个话题有些陈旧,但我才发现它.这是一个非常好的纯文件解决方案:

编辑:我稍微修改了代码,以使其更简单.

@echo off
setlocal EnableDelayedExpansion
if "%1" equ "Animate" goto %1

for /F %%a in ('echo prompt $H ^| cmd') do set "BS=%%a"
for /F %%a in ('copy /Z "%~F0" NUL') do set "CR=%%a"
cd . > input.txt
start "" /B "%~F0" Animate

set "input="
:nextKey
   set "key="
   for /F "delims=" %%K in ('xcopy /W "%~F0" "%~F0" 2^>NUL') do if not defined key set "key=%%K"
   if "!key:~-1!" equ "!CR!" goto endInput
   if "!key:~-1!" equ "!BS!" (
      if defined input set "input=%input:~0,-1%"
   ) else (
      set "input=%input%!key:~-1!"
   )
   set /P "=%input%" > input.txt < NUL
goto nextKey
:endInput
del input.txt
echo/
echo/
echo Input read: "%input%"
goto :EOF


:Animate
set "banner=                              Enter your name please                              "
set m=0
:loop
   if not exist input.txt exit
   set /A m=(m+1)%%51
   cls
   echo/
   echo/     !banner:~%m%,31!
   echo/
   echo/
   if exist input.txt (type input.txt) else exit
   ping -n 1 -w 300 localhost > NUL
   ping -n 1 -w 300 localhost > NUL
   ping -n 1 -w 300 localhost > NUL
goto loop

在该解决方案中,动画"徽标"被横幅替换,但是显示一系列文件的方法实际上是相同的.