如何在vala中更改Gtk.Label的字体大小？

Question

我是Vala/Gtk的新手,我正在尝试改变Gtk.Label的字体大小,但我找不到一个好方法.

我发现我可以使用这样的标记:

    var welcome_message = new Gtk.Label ("<span size='17000'>Hello</span>");
    welcome_message.set_use_markup (true);

但它似乎有点hackish.做正确的方法是什么？

Answer 1

感谢lethalman和nemequ.

我认为这可能对某人有所帮助,所以这里是一个如何使用Vala的CSS的小例子.

using Gtk;

public class StyleApp1 : Gtk.Window
{
    public StyleApp1() 
    {

        this.title = "Style app example";
        this.set_border_width (10);
        this.set_position (Gtk.WindowPosition.CENTER);

        this.set_default_size (350, 200);
        this.destroy.connect (Gtk.main_quit);

        var screen = this.get_screen ();
        var css_provider = new Gtk.CssProvider();

        string path = "styleapp1.css";

        // test if the css file exist
        if (FileUtils.test (path, FileTest.EXISTS))
        {
            try {
                css_provider.load_from_path(path);
                Gtk.StyleContext.add_provider_for_screen(screen, css_provider, Gtk.STYLE_PROVIDER_PRIORITY_USER);
            } catch (Error e) {
                error ("Cannot load CSS stylesheet: %s", e.message);
            }
        }

        var box = new Gtk.Box (Gtk.Orientation.VERTICAL, 10);
        this.add (box);

        var label = new Gtk.Label ("Thank you");
        box.add (label);

        var label2 = new Gtk.Label ("Stackoverflow");
        label2.get_style_context().add_class("my_class");
        box.add (label2);
    }
}

static int main(string[] args) {
    Gtk.init(ref args);

    StyleApp1 win = new StyleApp1();
    win.show_all();

    Gtk.main();
    return 0;
}

和styleapp1.css文件:

GtkWindow {
    font-size: 17px;
}

.my_class {
    color: pink;
}

注意:如果您使用add_provider而不是add_provider_for_screen.您必须为要自定义的每个窗口小部件使用add_provider.