创建唯一的文件名Windows批处理

Question

我看过很多关于创建一个独特文件名的帖子,从天真的%TIME%到合理的(但不足)%RANDOM%.使用wmic os get localdatetime更好,但它仍然可以在多个CPU /核心机器上失败.在多核计算机上运行5+ shell时,以下脚本最终会失败.

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION

FOR /L %%i IN (0, 1, 1000) DO (
    FOR /F "usebackq" %%x IN (`wmic os get localdatetime ^| find "."`) do (set MYDATE=%%x)
    ECHO MYDATE is now !MYDATE!
    IF EXIST testuniq_!MYDATE!.txt (
        ECHO FAILED ON !MYDATE!
        GOTO TheEnd
    )
    COPY NUL >testuniq_!MYDATE!.txt
)

:TheEnd
EXIT /B 0

有没有人有可靠的方法在shell脚本中创建一个唯一的文件名？

Answer 1

任何依赖于随机数的系统理论上都会失败,即使是使用GUID的系统也是如此.但世界似乎已经接受了GUID足够好.我已经看到在某处使用CSCRIPT JScript生成GUID的代码.

还有其他方法:

首先,我假设您正在尝试创建一个唯一的临时文件.由于文件将在您的流程结束后被删除,您所要做的就是在资源上建立一个独占锁,该资源的名称是临时文件名的衍生物.(实际上我反过来 - 临时名称来自锁定的资源名称).

重定向在输出文件上建立了一个独占锁,所以我只是从时间中得到一个名称(使用0.01秒精度),并尝试在用户的临时文件夹中锁定具有该名称的文件.如果失败了,我会回来再试一次,直到我成功为止.一旦我获得成功,我保证拥有该锁的唯一所有权和所有衍生物(除非有人故意破坏系统).

一旦我的进程终止,锁将被释放,并且稍后可以重用具有相同名称的临时文件.但是脚本通常会在终止时删除临时文件.

@echo off
setlocal

:getTemp
set "lockFile=%temp%\%~nx0_%time::=.%.lock"
set "tempFile=%lockFile%.temp"
9>&2 2>nul (2>&9 8>"%lockFile%" call :start %*) || goto :getTemp

:: Cleanup
2>nul del "%lockFile%" "%tempFile%"
exit /b


:start
:: Your code that needs the temp file goes here. This routine is called with the
:: original parameters that were passed to the script. I'll simply write some
:: data to the temp file and then TYPE the result.
>"%tempFile%" echo The unique tempfile for this process is "%tempfile%"
>>"%tempFile%" echo(%*
type "%tempFile%"
exit /b

由于名称冲突而导致的循环应该很少,除非您真的在强调系统.如果是这样,如果使用WMIC OS GET LOCALDATETIME而不是,则可以将循环的几率降低10倍%TIME%.

如果您正在寻找持久的唯一名称,那么问题就更难了,因为您无法无限期地维护锁定.对于这种情况,我建议使用WMIC OS LocalDateTime方法,并结合两次名称冲突检查.

第一次检查只是验证文件尚不存在.但这是竞争条件 - 两个进程可以同时进行检查.第二次检查创建文件(空)并在其上建立临时排他锁.诀窍是确保锁定的维护时间比另一个进程检查文件是否存在所需的时间长.我很懒,所以我只是使用TIMEOUT建立一个等待时间超过1秒的方式.

:getUniqueFile例程需要三个参数 - 基本名称,扩展名和要存储结果的变量名称.基本名称可以包括驱动器和路径信息.任何路径信息都必须有效,否则例程将进入无限循环.这个问题可以解决.

@echo off
setlocal

:: Example usage
call :getUniqueFile "d:\test\myFile" ".txt" myFile
echo myFile="%myFile%"
exit /b

:getUniqueFile  baseName  extension  rtnVar
setlocal
:getUniqueFileLoop
for /f "skip=1" %%A in ('wmic os get localDateTime') do for %%B in (%%A) do set "rtn=%~1_%%B%~2"
if exist "%rtn%" (
  goto :getUniqueFileLoop
) else (
  2>nul >nul (9>"%rtn%" timeout /nobreak 1) || goto :getUniqueFileLoop
)
endlocal & set "%~3=%rtn%"
exit /b

应保证上面的内容为给定路径返回一个新的唯一文件名.在锁定检查期间建立一些执行命令的优化空间很大,需要"足够长"而不是"太长"

Answer 2

您可以使用certutil这样%date% %time%的%random%种子进行 base64 编码：

@echo off
setlocal

:: generate unique ID string
>"%temp%\~%~n0.%username%.a" echo %username%%date%%time%%random%
>NUL certutil -encode "%temp%\~%~n0.%username%.a" "%temp%\~%~n0.%username%.b"
for /f "usebackq EOL=- delims==" %%I in ("%temp%\~%~n0.%username%.b") do set "unique_id=%%I"
del "%temp%\~%~n0.%username%.a" "%temp%\~%~n0.%username%.b"

echo %unique_id%

如果多个用户从同一目录运行相同的脚本，我将添加%username%到临时文件中以避免进一步冲突。我想你可以替换%random%使用%username%了同样的效果。如果单个用户同时执行相同的代码块两次，那么您只会遇到冲突。

（编辑：添加%username%为唯一性的种子。）