计算任意列数的百分比

Question

鉴于此示例输入:

ID     Sample1     Sample2      Sample3
One      10          0            5
Two      3           6            8
Three    3           4            7

我需要使用AWK生成此输出:

ID    Sample1 Sample2 Sample3
One   62.50   0.00    25.00
Two   18.75   60.00   40.00
Three 18.75   40.00   35.00

这就是我解决它的方式:

function percent(value, total) {
    return sprintf("%.2f", 100 * value / total)
}
{
    label[NR] = $1
    for (i = 2; i <= NF; ++i) {
        sum[i] += col[i][NR] = $i
    }
}
END {
    title = label[1]
    for (i = 2; i <= length(col) + 1; ++i) {
        title = title "\t" col[i][1]
    }
    print title
    for (j = 2; j <= NR; ++j) {
        line = label[j]
        for (i = 2; i <= length(col) + 1; ++i) {
            line = line "\t" percent(col[i][j], sum[i])
        }
        print line
    }
}

这在GNU AWK(awk在Linux中,gawk在BSD中)中工作正常,但在BSD AWK中没有,我得到此错误:

$ awk -f script.awk sample.txt
awk: syntax error at source line 7 source file script.awk
 context is
          sum[i] += >>>  col[i][ <<<
awk: illegal statement at source line 7 source file script.awk
awk: illegal statement at source line 7 source file script.awk

似乎问题在于多维数组.我想让这个脚本也能在BSD AWK中运行,所以它更具可移植性.

有没有办法改变它,使其在BSD AWK中工作？

Answer 1

尝试使用伪二维形式。代替

col[i][NR]

使用

col[i,NR]

那是一个一维数组，关键是连接的字符串：i SUBSEP NR