vba电子邮件嵌入图像未显示

Question

vba电子邮件嵌入图像未显示

Joh*_*ohn 5 embed email outlook vba image

我在这里有一个奇怪的经历。我在使用 src=cid 将徽标或图像嵌入电子邮件时遇到了很多问题...发现如果不设置大小，它就不会显示。

我有一个 Access 应用程序要发送，但已使用 Excel 将其分解为下面的代码。

但

如果我显示电子邮件然后发送它，它现在可以正常工作。根本不做其他任何事情。只显示然后发送。

如果我直接从 vba 发送，图像将无法正常显示。附件符号显示，Outlook 本身会将图像内联，但说，gmail，不会。这不是 gmail 的错，因为 Outlook 中显示了 attachmet 符号。如果我显示然后发送，则不会。

我怀疑它仍然与尺寸或放置有关。如果没有宽度部分，Outlook 仍会在正确的位置显示图像，但仍显示为附件。所以当你显示并按下发送时，我必须有另一个属性集或其他东西。我不知道什么！

希望有人可以提供帮助或有想法！我不是 HTLM 中最强的，所以这可能很简单......

谢谢

约翰

Sub test()
    Dim oApp As Outlook.Application
    Dim oEmail As MailItem
    Dim colAttach As Outlook.Attachments
    Dim oAttach As Outlook.Attachment

    'create new Outlook MailItem
    Set oApp = CreateObject("Outlook.Application")
    Set oEmail = oApp.CreateItem(olMailItem)

    'add graphic as attachment to Outlook message
    'change path to graphic as needed
    Set colAttach = oEmail.Attachments
    Set oAttach = colAttach.Add("C:\temp\logo.jpg")
    oEmail.Close olSave

    'change the src property to 'cid:your picture filename'
    'it will be changed to the correct cid when its sent.
    oEmail.HTMLBody = "<BODY><IMG src=""cid:logo.jpg"" width=200> </BODY>"
    oEmail.Save
    oEmail.To = "someemailtogoinhere@gmail.com"
    oEmail.Subject = "test"
    oEmail.Display
    'oEmail.Send

    Set oEmail = Nothing
    Set colAttach = Nothing
    Set oAttach = Nothing
    Set oApp = Nothing
End Sub

Run Code Online (Sandbox Code Playgroud)

Answer 1

Joh*_*ohn 7

只是为了发布有效的简单代码形式。非常感谢@Eugene Astafiev。

Sub test()
    Dim oApp As Outlook.Application
    Dim oEmail As MailItem
    Dim colAttach As Outlook.Attachments
    Dim oAttach As Outlook.Attachment

    Dim olkPA As Outlook.PropertyAccessor

    Const PR_ATTACH_CONTENT_ID = "http://schemas.microsoft.com/mapi/proptag/0x3712001F"

    'create new Outlook MailItem
    Set oApp = CreateObject("Outlook.Application")
    Set oEmail = oApp.CreateItem(olMailItem)
    'add graphic as attachment to Outlook message
    'change path to graphic as needed
    Set colAttach = oEmail.Attachments
    Set oAttach = colAttach.Add("C:\temp\logo.jpg")
    Set olkPA = oAttach.PropertyAccessor

    olkPA.SetProperty PR_ATTACH_CONTENT_ID, "logo.jpg"

    oEmail.Close olSave
    'change the src property to 'cid:your picture filename'
    'it will be changed to the correct cid when its sent.
    oEmail.HTMLBody = "<BODY><IMG src=""cid:logo.jpg""> </BODY>"

    oEmail.Save
    oEmail.To = "someemail@gmail.com"
    oEmail.Subject = "test"
    oEmail.Send

    Set oEmail = Nothing
    Set colAttach = Nothing
    Set oAttach = Nothing
    Set oApp = Nothing

End Sub

Run Code Online (Sandbox Code Playgroud)

Answer 2

Eug*_*iev 4

您需要使用 Attachment.PropertyAccessor 在附件上设置 PR_ATTACH_CONTENT_ID 属性 (DASL - http://schemas.microsoft.com/mapi/proptag/0x3712001F )。请注意，Attachment 类的 PropertyAccessor 属性是在 Outlook 2007 中添加的。

您可能会发现如何使用 VBA 在 Outlook 邮件中嵌入图像？链接有帮助。

归档时间：	11 年，2 月前
查看次数：	18727 次
最近记录：	6 年，7 月前