F#函数调用语法混乱

Question

我有一段代码:

links
    |> Seq.map (fun x -> x.GetAttributeValue ("href", "no url"))

我想改写为:

links
    |> Seq.map (fun x -> (x.GetAttributeValue "href" "no url"))

但是F#编译器似乎并不喜欢这样.我认为这两个函数调用是可以互换的:

f (a, b)
(f a b)

我得到的错误是:

无法从此代码位置访问带有2个参数的成员或对象构造函数"GetAttributeValue".方法'GetAttributeValue'的所有可访问版本都有2个参数.

这似乎很有趣,因为它似乎表明它需要我给它的东西.我在这里错过了什么？

Answer 1

F#中的常规函数​​调用是在没有括号的情况下编写的,参数由空格分隔.定义几个参数的函数的简单方法是写这个:

let add a b = a + b

正如Pascal所指出的,这种指定参数的方式称为currying - 这个想法是函数只接受一个参数,结果是一个接受第二个参数并返回实际结果(或另一个函数)的函数.当调用像这样的简单函数时,你会写add 10 5,编译器(原则上)将其解释为((add 10) 5).这有一些很好的优点 - 例如,它允许您使用部分函数应用程序,其中您只指定函数的前几个参数:

let addTen = add 10 // declares function that adds 10 to any argument
addTen 5  // returns 15
addTen 9  // returns 19

此功能在处理列表时非常有用:

// The code using explicit lambda functions..
[ 1 .. 10 ] |> List.map (fun x -> add 10 x) 

// Can be rewritten using partial function application:
[ 1 .. 10 ] |> List.map (add 10) 

现在,让我们进入令人困惑的部分 - 在F#中,您还可以使用元组,元组是简单的数据类型,允许您将多个值组合成单个值(请注意,元组与函数无关).你可以写例如:

let tup = (10, "ten")    // creating a tuple
let (n, s) = tup         // extracting elements of a tuple using pattern 
printfn "n=%d s=%s" n s  // prints "n=10 s=ten"

当你编写一个函数,在括号中用逗号分隔参数时,你实际上是在写一个函数,它接受一个参数,它是一个元组:

// The following function:
let add (a, b) = a * b

// ...means exactly the same thing as:
let add tup = 
  let (a, b) = tup  // extract elements of a tuple
  a * b

// You can call the function by creating tuple inline:
add (10, 5)
// .. or by creating tuple in advance
let t = (10, 5)
add t

这是一个不同类型的函数 - 它需要一个参数,它是一个元组,而第一个版本是一个带有两个参数的函数(使用currying).

在F#中,情况有点复杂 - .NET方法显示为将元组作为参数的方法(因此您可以使用带括号的符号来调用它们),但它们有些限制(例如,您无法创建元组)首先,然后调用方法,只给它元组).此外,编译的F#代码实际上并不以curry形式生成方法(因此您不能直接从C#使用部分函数应用程序).这是由于性能原因 - 大多数情况下,您指定所有参数,这可以更有效地实现.

但是,原理是函数要么采用多个参数,要么将元组作为参数.