批量选择菜单？

Question

是否可以有一个批处理脚本来要求用户（在 CMD 中）选择当前 PC 是主机还是客户端？用户使用向上或向下键盘箭头选择一个选项，然后按 Enter 键确认。

我已经做了一些谷歌搜索，但我只能找到用于输入选择编号的代码。

Answer 1

如果没有第三方程序的帮助，批处理文件无法读取光标控制键。但是，您可以通过以下过程使用基于 DOSKEY 命令的有趣技巧：

1. 清除以前的 DOSKEY 历史记录。
2. 执行几个读取菜单选项的 SET /P 命令，以便 DOSKEY 历史记录充满它们。
3. 向键盘发送 F7 键。
4. 执行 SET /P "OPTION=Prompt: "; 该命令的输入是通过DOSKEY 的选择菜单完成的。

虽然此方法需要借助 JScript 编程语言，但从 XP 开始的所有 Windows 版本都包含此方法。将以下代码复制并粘贴为批处理 .BAT 文件：

@if (@CodeSection == @Batch) @then


@echo off
setlocal EnableDelayedExpansion

rem Multi-line menu with options selection via DOSKEY
rem Antonio Perez Ayala

rem Define the options
set numOpts=0
for %%a in (First Second Third Fourth Fifth) do (
   set /A numOpts+=1
   set "option[!numOpts!]=%%a Option"
)
set /A numOpts+=1
set "option[!numOpts!]=exit"

rem Clear previous doskey history
doskey /REINSTALL
rem Fill doskey history with menu options
cscript //nologo /E:JScript "%~F0" EnterOpts
for /L %%i in (1,1,%numOpts%) do set /P "var="

:nextOpt
cls
echo MULTI-LINE MENU WITH OPTIONS SELECTION
echo/
rem Send a F7 key to open the selection menu
cscript //nologo /E:JScript "%~F0"
set /P "var=Select the desired option: "
echo/
if "%var%" equ "exit" goto :EOF
echo Option selected: "%var%"
pause
goto nextOpt


@end

var wshShell = WScript.CreateObject("WScript.Shell"),
    envVar = wshShell.Environment("Process"),
    numOpts = parseInt(envVar("numOpts"));

if ( WScript.Arguments.Length ) {
   // Enter menu options
   for ( var i=1; i <= numOpts; i++ ) {
      wshShell.SendKeys(envVar("option["+i+"]")+"{ENTER}");
   }
} else {
   // Enter a F7 to open the menu
   wshShell.SendKeys("{F7}{HOME}");
}

上一个程序的输出示例：

更多详细信息请参阅这篇文章。