如何在gradle中复制文件？

Question

我正在尝试将war存档部署到Tomcat中.这是我编写的构建脚本:

apply plugin : 'war'

task deploy (dependsOn: war){
    copy {
        from "build/libs"
        into "E:/apache-tomcat-8.0.14/webapps"
        include "*.war"
    }
}

但它没有效果.有没有war在根webapps.Gradle输出:

:compileJava UP-TO-DATE
:processResources UP-TO-DATE
:classes UP-TO-DATE
:war
:deploy

怎么了？

请不要建议我使用任何tomcat-cargo插件.我只是想知道如何修复特定的文件复制任务.

Answer 1

任务中的代码在配置阶段运行,而不是在执行阶段运行.因此它在战争任务完成之前运行.任务看起来应该是这样的

task deploy (dependsOn: war) << {
    ...
}

要么

task deploy (dependsOn: war) {
    doLast {
        ...
    }
}

或者,更好的是,您应该将任务设置为复制任务并配置它,而不是定义在执行时以命令方式执行复制的任务:

task deploy (dependsOn: war, type: Copy) {
    from "build/libs"
    into "E:/apache-tomcat-8.0.14/webapps"
    include "*.war"
}

Answer 2

如果您需要从单个源复制到多个目标，您还可以尝试以下操作：

task deploy (dependsOn: war, type: Copy) {
    // define your multiple directories
    def multipleDest = ["$buildDir/libs/folder1", "$buildDir/libs/folder2", "$buildDir/libs/folder3"]

    // get the output dirs
    multipleDest.each { outputDir ->
        outputs.dir outputDir
    }
    // copy to all of them
    doLast {
        multipleDest.each { outputDir ->
            copy {
                from "$buildDir/*.war"
                into outputDir
            }
        }
    }
}