这个IL指令中-2的含义是什么？

Question

我发现了IL code一个简单的程序:

long x = 0;
for(long i = 0;i< int.MaxValue * 2L; i++)
{
    x = i;
}

Console.WriteLine(x);

我在发布模式下构建此代码并IL code生成:

.method private hidebysig static void  Main(string[] args) cil managed
{
  .entrypoint
  // Code size       28 (0x1c)
  .maxstack  2
  .locals init ([0] int64 x,
           [1] int64 i)
  IL_0000:  ldc.i4.0
  IL_0001:  conv.i8
  IL_0002:  stloc.0
  IL_0003:  ldc.i4.0
  IL_0004:  conv.i8
  IL_0005:  stloc.1
  IL_0006:  br.s       IL_000f
  IL_0008:  ldloc.1
  IL_0009:  stloc.0
  IL_000a:  ldloc.1
  IL_000b:  ldc.i4.1
  IL_000c:  conv.i8
  IL_000d:  add
  IL_000e:  stloc.1
  IL_000f:  ldloc.1
  IL_0010:  ldc.i4.s   -2
  IL_0012:  conv.u8
  IL_0013:  blt.s      IL_0008
  IL_0015:  ldloc.0
  IL_0016:  call       void [mscorlib]System.Console::WriteLine(int64)
  IL_001b:  ret
} // end of method Program::Main

除了这个,我几乎找出了所有的解释:

 IL_0010:  ldc.i4.s   -2

现在这个insruction应该推入int.MaxValue * 2L堆栈,然后blt.s将它与之比较i,如果i小于值返回到IL_0008.But,我无法弄清楚它为什么加载-2？如果我改变循环如下:

for(long i = 0;i < int.MaxValue * 3L; i++)
{
     x = i;
}

它加载预期值:

IL_0010:  ldc.i8     0x17ffffffd

那么-2这段代码的含义是什么？

Answer 1

int.MaxValue * 2L是一个64位数字,但仍然适合32位(4,294,967,294,或0xFFFFFFFE).因此,编译器正在加载0xFFFFFFFE(解释为时等于-2 Int32),然后将其扩展为无符号的64位值.

它使用带符号形式的原因是,当被解释为有符号值时,该数字-2适合单个带符号的字节(-128to 127),这意味着编译器能够发出短格式ldc.i4.s操作码以从中加载32位值.单字节.它只需要2个字节来加载32位有符号整数,另外1个字节将其转换为64位值 - 这比使用64位加载指令后跟一个完整的8字节无符号整数要好得多.