使用Hash :: Merge将数组合并到数组中

Question

我正在尝试合并包含一个或多个数组的两个哈希值Hash::Merge.例如:

use strict;
use warnings;
use feature qw(say);

use Data::Dump qw(dump);
use Hash::Merge qw(merge);

my $h1 = { a => [ { aa => 1 }, 3 ] };
my $h2 = { a => [ { bb => 2 } ] };

my $hLeft  = merge( $h1, $h2 );
my $hRight = merge( $h2, $h1 );

say "  hLeft: " . dump($hLeft);
say " hRight: " . dump($hRight);

my $hDesired = { a => [ { aa => 1, bb => 2 }, 3 ] };
say "Desired: " . dump($hDesired);

这给出了输出:

  hLeft: { a => [{ aa => 1 }, 3, { bb => 2 }] }
 hRight: { a => [{ bb => 2 }, { aa => 1 }, 3] }
Desired: { a => [{ aa => 1, bb => 2 }, 3] }

如何使用正确的输出Hash::Merge？

Answer 1

合并数组的默认行为是追加它们：

sub { [ @{$_[0]}, @{$_[1]} ] },

为了获得不同的行为，必须使用Hash::Merge::specify_behavior.

以下解决方案是 LEFT_PRECEDENT，并将数组元素合并到元素：

use strict;
use warnings;
use feature qw(say);

use Data::Dump qw(dump);
use Hash::Merge qw(merge);

Hash::Merge::specify_behavior(
    {   'SCALAR' => {
            'SCALAR' => sub { $_[0] },
            'ARRAY'  => sub { $_[0] },
            'HASH'   => sub { $_[0] },
        },
        'ARRAY' => {
            'SCALAR' => sub { [ @{ $_[0] }, $_[1] ] },
            'ARRAY'  => sub {
                my ( $left, $right ) = @_;

                my @merged = @$left;
                my @to_add = @$right;

                for (@merged) {
                    last if !@to_add;
                    $_ = Hash::Merge::merge( $_, shift @to_add );
                }

                return [ @merged, @to_add ];
            },
            'HASH'  => sub { [ @{ $_[0] }, values %{ $_[1] } ] },
        },
        'HASH' => {
            'SCALAR' => sub { $_[0] },
            'ARRAY'  => sub { $_[0] },
            'HASH'   => sub { Hash::Merge::_merge_hashes( $_[0], $_[1] ) },
        },
    },
    'My Behavior',
);

my $h1 = { a => [ { aa => 1 }, 3 ] };
my $h2 = { a => [ { bb => 2 } ] };

my $merged = merge( $h1, $h2 );
say "Merged: " . dump($merged);

输出：

Merged: { a => [{ aa => 1, bb => 2 }, 3] }