如何将数组传递给VBA中的函数？

Question

我正在尝试编写一个接受数组作为参数的函数.该数组可以包含任意数量的元素.

Function processArr(Arr() As Variant) As String
    Dim N As Variant  
    dim finalStr as string      
    For N = LBound(Arr) To UBound(Arr)
        finalStr = finalStr & Arr(N)
    Next N
    processArr = finalStr
End Function

以下是我尝试调用该函数的方法:

Sub test()
    Dim fString as string
    fString = processArr(Array("foo", "bar"))
End Sub

我收到一个错误说:

编译错误:类型不匹配:数组或用户定义的预期类型.

我究竟做错了什么？

Answer 1

这似乎没必要,但VBA是一个奇怪的地方.如果你声明一个数组变量,然后使用它Array()然后将变量传递给你的函数,VBA将很高兴.

Sub test()
    Dim fString As String
    Dim arr() As Variant
    arr = Array("foo", "bar")
    fString = processArr(arr)
End Sub

您的功能processArr()也可以写成:

Function processArr(arr() As Variant) As String
    processArr = Replace(Join(arr()), " ", "")
End Function

如果你是整个简洁的事情.

Answer 2

在将声明更改为此后,您的功能对我有用...

Function processArr(Arr As Variant) As String

你也可以考虑ParamArray这样......

Function processArr(ParamArray Arr() As Variant) As String
    'Dim N As Variant
    Dim N As Long
    Dim finalStr As String
    For N = LBound(Arr) To UBound(Arr)
        finalStr = finalStr & Arr(N)
    Next N
    processArr = finalStr
End Function

然后像这样调用函数......

processArr("foo", "bar")