D特征 - 完整数据成员列表

Question

我试图使用以下代码从类中获取整数数据成员的列表:

import std.stdio;
import std.traits;

class D
{
    static string[] integralMembers = getIntegralMembers();

    static string[] getIntegralMembers()
    {
        auto allMembers = __traits(allMembers, D);

        string[] tmp = new string[allMembers.length];
        int ct = 0;

        for(int i = 0; i != allMembers.length; ++i) {
            bool isInteg = __traits(isIntegral, __traits(getMember, D, allMembers[i]));
            if(isInteg) {
                tmp[ct++] = allMembers[i];
            }
        }

        string[] ret = new string[ct];

        for(int i = 0; i != ct; ++i) {
            ret[i] = tmp[i];
        }

        return ret;
    }

    int a;
    this() { }
    ~this() { }
}

void main()
{
    auto integralMembers = D.integralMembers;

    foreach(mem; integralMembers)
    {
        writeln(mem);
    }
}

但是,编译失败了这些错误:

main.d(17): Error: variable i cannot be read at compile time
main.d(17): Error: expression expected as second argument of __traits getMember
main.d(19): Error: variable i cannot be read at compile time
main.d(7):        called from here: getIntegralMembers()

如何编译此代码？

Answer 1

即使该函数仅在该程序中的编译期间运行,它仍然必须可编译为可在运行时运行的函数.

1. 您需要声明allMembers为清单常量:

   enum allMembers = __traits(allMembers, D);
   

   allMembers是一个元组.如果使用auto,它将被保存为"堆栈"上的字符串元组,成为运行时值,因此无法进行编译时评估__traits.

2. 你需要使用foreach而不是for.foreach对元组的特殊之处在于它将静态展开,因此可以访问索引(和值)__traits.

固定程序:

import std.stdio;
import std.traits;

class D
{
    static string[] integralMembers = getIntegralMembers();

    static string[] getIntegralMembers()
    {
        enum allMembers = __traits(allMembers, D);

        string[] tmp = new string[allMembers.length];
        int ct = 0;

        foreach(i, member; allMembers) {
            bool isInteg = __traits(isIntegral, __traits(getMember, D, member));
            if(isInteg) {
                tmp[ct++] = allMembers[i];
            }
        }

        string[] ret = new string[ct];

        for(int i = 0; i != ct; ++i) {
            ret[i] = tmp[i];
        }

        return ret;
    }

    int a;
    this() { }
    ~this() { }
}

void main()
{
    auto integralMembers = D.integralMembers;

    foreach(mem; integralMembers)
    {
        writeln(mem);
    }
}