XSLT 在每个字符上拆分字符串

Question

我有一个类似的字符串：“ABCDEFGHI”我希望输出为 A,B,C,D,E,F,G,H,I in xslt-

我一直在使用 -

<xsl:variable name="string_Comma_Delimited">a,b,c,d,e,f,g,h,i</xsl:variable>

<xsl:call-template name="parseString">
  <xsl:with-param name="list" select="$string_Comma_Delimited"/>
 </xsl:call-template>


<xsl:template name="parseString">
<xsl:param name="list"/>

<xsl:if test="contains($list, ',')">
     <fo:table-cell border-width="0.000pt " border-style="solid" border-color="rgb(0,0,0)" padding-top="4.000pt">
        <fo:block-container  height="6mm" border-width="0.200pt" border-style="solid" border-color="rgb(0,0,0)" text-align="center">
        <fo:block text-align="center">
                <xsl:value-of select="substring-before($list, ',')"/>
        </fo:block>
        </fo:block-container>
    </fo:table-cell>
 <xsl:call-template name="parseString">
  <xsl:with-param name="list" select="substring-after($list, ',')"/>
 </xsl:call-template>
</xsl:if>

</xsl:template>

Answer 1

您当前的模板用逗号分割字符串。要简单地将其拆分为每个字符，您仍然可以使用递归模板。模板所做的就是使用 输出第一个字符substring，然后，如果字符串的长度为 2 个或更多字符，则使用字符串的剩余部分递归调用模板。

尝试这个

<xsl:template name="parseString">
    <xsl:param name="text"/>
    <letter>
        <xsl:value-of select="substring($text, 1, 1)"/>
    </letter>
    <xsl:if test="string-length($text) > 1">
        <xsl:call-template name="parseString">
            <xsl:with-param name="text" select="substring($text, 2, string-length($text) - 1)"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

给定INDIA作为输入，以下是输出：

<letter>I</letter>
<letter>N</letter>
<letter>D</letter>
<letter>I</letter>
<letter>A</letter>

现在，如果您使用的是 XSLT 2.0，您可以使用该xsl:analyze-string函数来实现相同的

<xsl:template name="parseString">
    <xsl:param name="text"/>
    <xsl:analyze-string select="$text" regex=".">
        <xsl:matching-substring>
            <letter>
                <xsl:value-of select="." />
            </letter>
        </xsl:matching-substring>
    </xsl:analyze-string>
</xsl:template>

（当然，如果您使用的是 XSLT 2.0，您可以tokenize在第一种情况下使用以拆分逗号分隔的字符串）