Marpa解析器库是否支持错误恢复？

Question

我知道Perl的"Marpa" Earley解析器有很好的错误报告.

但我无法在其文档中或通过谷歌搜索找到它是否有错误恢复.

例如,大多数C/C++编译器都有错误恢复,用于报告多个语法错误,而其他编译器通常会在第一个错误时停止.

我实际上正在解析自然语言,并想知道在输入的一部分失败之后是否有重新同步和恢复解析的方法.

---

例如,对于那些可以理解它的人:

我正用老挝语解析音节.在老挝,一些元音是变音符号,它们被编码为单独的字符并在前一个辅音上方呈现.在解析来自老挝维基百科的随机文章时,我遇到了一些文本,其中这样的元音加倍.这在老挝正字法中是不允许的,所以必须是拼写错误.但我知道,在几个字符内,文字再次好.

无论如何,这是一个真实的例子,它引起了我对错误恢复或与令牌流重新同步的普遍兴趣.

Answer 1

处理Marpa中的错误有两种可能性.

"Ruby Slippers"解析

Marpa在扫描过程中保持了很多背景.我们可以使用这个上下文,以便解析器可以需要一些令牌,我们可以决定是否要将它提供给Marpa,即使它不在输入中.例如,考虑一种编程语言,它要求任何语句以分号结束.然后我们可以使用Ruby Slippers技术在特定位置插入分号,例如在行尾或封闭括号之前:

use strict;
use warnings;
use Marpa::R2;
use Data::Dump 'dd';

my $grammar = Marpa::R2::Scanless::G->new({
    source => \q{
        :discard ~ ws
        Block         ::= Statement+ action => ::array
        Statement     ::= StatementBody (STATEMENT_TERMINATOR) action => ::first
        StatementBody ::= 'statement'       action => ::first
                      |   ('{') Block ('}') action => ::first
        STATEMENT_TERMINATOR ~ ';'
        event ruby_slippers = predicted STATEMENT_TERMINATOR
        ws ~ [\s]+
    },
});
my $recce = Marpa::R2::Scanless::R->new({ grammar => $grammar });

my $input = q(
    statement;
    { statement }
    statement
    statement
);

for (
  $recce->read(\$input);
  $recce->pos < length $input;
  $recce->resume
) {
    ruby_slippers($recce, \$input);
}
ruby_slippers($recce, \$input);
dd $recce->value;

sub ruby_slippers {
    my ($recce, $input) = @_;
    my %possible_tokens_by_length;

    my @expected = @{ $recce->terminals_expected };
    for my $token (@expected) {
        pos($$input) = $recce->pos;

        if ($token eq 'STATEMENT_TERMINATOR') {
            # fudge a terminator at the end of a line, or before a closing brace
            if ($$input =~ /\G \s*? (?: $ | [}] )/smxgc) {
                push @{ $possible_tokens_by_length{0} }, [STATEMENT_TERMINATOR => ';'];
            }
        }
    }

    my $max_length = 0;
    for (keys %possible_tokens_by_length) {
        $max_length = $_ if $_ > $max_length;
    }
    if (my $longest_tokens = $possible_tokens_by_length{$max_length}) {
        for my $lexeme (@$longest_tokens) {
            $recce->lexeme_alternative(@$lexeme);
        }
        $recce->lexeme_complete($recce->pos, $max_length);

        return ruby_slippers($recce, $input);
    }
}

在ruby_slippers函数中,您还可以计算需要捏造令牌的频率.如果该计数超过某个值,则可以通过抛出错误来放弃解析.

跳过输入

如果您的输入可能包含不可解析的垃圾,那么如果没有找到任何词汇,您可以尝试跳过它.为此,该$recce->resume方法采用可选的position参数,其中将恢复正常的解析.

use strict;
use warnings;
use Marpa::R2;
use Data::Dump 'dd';
use Try::Tiny;

my $grammar = Marpa::R2::Scanless::G->new({
    source => \q{
        :discard ~ ws
        Sentence ::= WORD+ action => ::array
        WORD ~ 'foo':i | 'bar':i | 'baz':i | 'qux':i
        ws ~ [\s]+
    },
});
my $recce = Marpa::R2::Scanless::R->new({ grammar => $grammar });

my $input = '1) Foo bar: baz and qux, therefore qux (foo!) implies bar.';

try { $recce->read(\$input) };
while ($recce->pos < length $input) {
    # ruby_slippers($recce, \$input);
    try   {       $recce->resume                    }  # restart at current position
    catch { try { $recce->resume($recce->pos + 1) } }; # advance the position
    # if both fail, we go into a new iteration of the loop.
}
dd $recce->value;

虽然使用:discard匹配任何内容的词法可以实现相同的效果,但是如果必须进行过多的捏造,那么在我们的客户端代码中跳过允许我们中止解析.