从 RecordSet 填充字典

Question

我想知道是否有人可以帮助我。我正在尝试从 sql 表返回的记录集填充公共字典。

除了一部分外，一切似乎都很好。我不知道它是否没有正确计算字典中的键数，或者它们没有被正确输入，但是无论出于何种原因，当我尝试显示总计数时，它总是只返回 1（应该是大约 15) 并且只显示第一行详细信息。

任何人都可以帮忙吗？

Public UserList As New scripting.Dictionary
Sub UserDL()
Dim USList As Range
Dim USArr(0 To 11) As Variant

Call ConnecttoDB

Set Cmd = New adodb.Command: Set rs = New adodb.Recordset

With Cmd
    .CommandTimeout = 30
    .ActiveConnection = cn
    .CommandText = "CSLL.DLUsers"

    Set rs = .Execute
End With

With rs
    If Not .BOF And Not .EOF Then
        .MoveLast
        .MoveFirst
        While (Not .EOF)
            For i = 1 To 11
                USArr(i - 1) = rs(i)
            Next i

                With UserList
                    If Not .Exists(rs("Alias")) Then
                        .Add Key:=rs("Alias"), Item:=USArr
                    End If
                End With
            .MoveNext
        Wend
    End If
End With

IA = UserList.Items
Debug.Print UserList.Count & " Items in the dictionary"
For Each element In IA
    For i = 0 To 10
        Debug.Print element(i)
    Next i
Next element

Set Cmd = Nothing: Set rs = Nothing ': Set UserList = Nothing
End Sub

Answer 1

rs("Alias") 是一个 Field 对象。Field 对象的默认属性是 Value，所以通常只引用 Field 对象就给了我们我们想要的 - 值。但是，Dictionary 可以存储对象（作为值或键），因此当您添加对象时，它实际上存储的是对象而不是默认属性。因此，在您的代码中，您添加 rs("Alias") 作为键，即对象而不是值。当您移动到下一条记录时， rs("Alias") 仍然是同一个对象 - 只是值发生了变化。因此，当您检查密钥是否存在时，它确实存在。您需要添加 Value 属性作为键。

aa_dd 的答案有效的原因是因为它将值存储在一个变量中，然后将该值用作键，即不是 Field 对象。

另一种方法是显式使用 Field 对象的 Value 属性...

With UserList
    If Not .Exists(rs("Alias").Value) Then
        .Add Key:=rs("Alias").Value, Item:=USArr
    End If
End With