Windows:用于读取可执行文件的版本信息的命令行？

Question

Windows是否有可执行文件,我可以在命令shell中运行,它返回可执行文件(.exe)的版本号？

我看到很多问题显示如何使用不同的语言,并引用第三方软件来编写它,但我找不到一个简单的shell命令来执行它.如果我不需要安装任何东西,还有其他要点.

它必须以普通用户身份运行.不是管理员.

Answer 1

wmic datafile where name="C:\\Windows\\System32\\msiexec.exe" get Version /value 

你可以wmic用来做.您可以将其包装到批处理文件中

@echo off
    setlocal enableextensions

    set "file=%~1"
    if not defined file goto :eof
    if not exist "%file%" goto :eof

    set "vers="
    FOR /F "tokens=2 delims==" %%a in ('
        wmic datafile where name^="%file:\=\\%" get Version /value 
    ') do set "vers=%%a"

    echo(%file% = %vers% 

    endlocal

保存为(示例)getVersion.cmd并调用为getVersion.cmd "c:\windows\system32\msiexec.exe"

编辑以适应评论而不需要管理员权限.在这种情况下,混合cmd/javascript文件用于查询wmi.相同的用法

@if (@this==@isBatch) @then
@echo off
    setlocal enableextensions

    set "file=%~f1"
    if not exist "%file%" goto :eof

    cscript //nologo //e:jscript "%~f0" /file:"%file%"

    endlocal

    exit /b
@end
    var file = WScript.Arguments.Named.Item('file').replace(/\\/g,'\\\\');
    var wmi = GetObject('winmgmts:{impersonationLevel=impersonate}!\\\\.\\root\\cimv2')
    var files = new Enumerator(wmi.ExecQuery('Select Version from CIM_datafile where name=\''+file+'\'')) 

    while (!files.atEnd()){
        WScript.StdOut.WriteLine(files.item().Version);
        files.moveNext();
    };
    WScript.Quit(0)

Answer 2

如果您愿意并且能够使用PowerShell ......

(get-item -Path 'C:\Program Files\Java\jdk1.8.0_144\bin\java.exe').VersionInfo |
    Format-List -Force

如果必须在cmd.exe shell中运行它,则可以使用:

powershell -NoLogo -NoProfile -Command ^
    (get-item -Path 'C:\Program Files\Java\jdk1.8.0_152\bin\java.exe').VersionInfo ^| ^
        Format-List -Force

Answer 3

这只会给你文件版本：

wmic datafile where name='c:\\windows\\system32\\notepad.exe' get version

结果：

Version
6.1.7601.18917

Answer 4

set EXE='c:\firefox\firefox.exe'
powershell "(Get-Item -path %EXE%).VersionInfo.ProductVersion"