使用VBA创建自定义事件

Question

我正在努力了解如何使用VBA中的类模块创建自定义事件.

我把简单的下面的例子放在一起.你在A1和B1中放了一个值,然后重新激活工作表来计算两者的总和,然后我希望一个事件会触发警告计算,但没有任何反应.

对于解决这个例子的任何帮助我都非常感激.

类模块cCalc:

Dim m_wks As Worksheet
Public Event BeforeCalc()

Property Set Worksheet(wks As Worksheet)
    Set m_wks = wks
End Property

Public Sub Calc()
Dim dVal1 As Double
Dim dVal2 As Double

    With m_wks
        dVal1 = .Range("A1").Value
        dVal2 = .Range("B1").Value

        RaiseEvent BeforeCalc
        .Range("C1").Value = dVal1 + dVal2
    End With


End Sub

在mGlobal模块中:

Public gCalc As cCalc

在Sheet1背后的代码中:

Private WithEvents calcEvent As cCalc

Private Sub calcEvent_BeforeCalc()
    MsgBox "About to Calc!", vbInformation
End Sub

Private Sub Worksheet_Activate()
    Set gCalc = New cCalc

    Set gCalc.Worksheet = ActiveSheet
    gCalc.Calc

End Sub

Answer 1

您不能在模块中声明事件驱动类。您需要将 gModule 中的 cCalc 引用设置为等于您在 Sheet1 中声明的 WithEvents 对象。将 Sheet1 中的代码更改为我在下面编写的代码，它将起作用：

Private WithEvents calcEvent As cCalc

Private Sub calcEvent_BeforeCalc()
    MsgBox "About to Calc!", vbInformation
End Sub

Private Sub Worksheet_Activate()
    Set calcEvent = New cCalc          'Instantiate the WithEvents object above
    Set mGlobal.gCalc = calcEvent      'Set the object declared in gModule

    Set mGlobal.gCalc.Worksheet = ActiveSheet
    mGlobal.gCalc.Calc
End Sub

请注意，这是使用您放入 gModule 中的变量...实际调用的事件仍然是calcEvent_BeforeCalc()，这很好，因为这样您可以在 gModule 中定义 n 个对象，这些对象都会触发同一事件事件触发时的代码。

为了简化代码，您可以随时编写：

Private Sub Worksheet_Activate()
    Set calcEvent = New cCalc
    Set calcEvent.Worksheet = ActiveSheet
    calcEvent.Calc
End Sub