在destructuring-bind中声明未使用的变量的任何好方法？

Question

我无法想象,有没有办法在erlang中输入_之类的东西,在destructuring-bind中使用"未使用的值"？

例如,我们有类似的东西:

(destructuring-bind ((_SNIPPET
                               (_TITLE . title)
                               (_DESCRIPTION . description)
                               _RESOURCE-ID (_VIDEO-ID . video-id)))) entry
                (declare (ignore 
                          _SNIPPET _TITLE _DESCRIPTION _RESOURCE-ID _VIDEO-ID))
                (list video-id title description)))

如果不为每个未使用的值放置特定变量,那就太棒了,写下这样的东西:

 (destructuring-bind ((_
                         (_ . title)
                         (_ . description)
                         (_ (_ . video-id)))) entry
                    (list video-id title description)))

有没有办法通过标准解构 - 绑定或任何其他标准宏来获得这种行为？或者我必须使用一些类似ML的模式匹配库,如果是这样 - 哪一个？

Answer 1

这是不可能的DESTRUCTURING-BIND(你不能多次使用一个变量,一些编译器会抱怨).您可以枚举变量,_1,_2,...但你不得不忽视它们.

LOOP 可以做到:

CL-USER 23 > (loop for ((a b nil c) nil d) in '(((1 2 3 4) 5 6)
                                                ((1 2 3 4) 5 6))
                   collect (list a b c d))
((1 2 4 6) (1 2 4 6))

NIL 用作通配符变量.

你可以重用LOOP宏:

(defmacro match-bind (pattern object &body body)
  `(loop with ,pattern = ,object
         while nil
         finally (return (progn ,@body))))

CL-USER 37 > (match-bind ((a b nil c) nil d)
                 '((1 2 3 4) 5 6)
               (list a b c d))
(1 2 4 6)

您可以使用LET-MATCH某些库中的一些.例如:https://github.com/schani/clickr/blob/master/let-match.lisp 可能有更多花哨的版本.

Answer 2

这种语言没有内置任何东西. Rainer Joswig的回答指出循环可以进行一些解构,但它并没有那么多.在这个答案的早期版本中,我建议遍历解构lambda列表并收集以_开头的所有符号的列表,并向表单添加一个声明来忽略这些变量.一个更安全的版本用一个新变量替换每个变量(这样就没有重复的变量),并忽略它们.就像这样的东西

(destructuring-bind (_a (_b c)) object
  c)

会扩大到

(destructuring-bind (#:g1 (#:g2 c)) object
  (declare (ignore #:g1 #:g2))
  c)

如果您只使用3.4.4.1.1 Lambda Lists的数据导向解构中描述的"数据导向",则此方法将正常工作.但是,如果你使用的是Lambda Lists的3.4.4.1.2 Lambda-list-directed Destructuring中描述的"lambda-list-directed"方法,你可以在其中使用lambda-list关键字,如&optional,&key等,那么事情要复杂得多,因为你不应该在那些部分中替换变量.例如,如果你有

&optional (_x '_default-x)

可以_x用某些东西替换,但不是_default-x,因为后者不是一种模式.但是,在Lisp中,代码是数据,因此我们仍然可以编写一个映射在destructuring-lambda-list上的宏,并仅替换为模式的位置.这里有点毛茸茸的代码.这需要一个函数和一个解构lambda列表,并调用lambda列表中每个模式变量的函数,以及参数的类型(整体,必需,可选等).

(defun map-dll (fn list)
  (let ((result '())
        (orig list)
        (keywords '(&allow-other-keys &aux &body
                    &key &optional &rest &whole)))
    (labels ((save (x)
               (push x result))
             (handle (type parameter)
               (etypecase parameter
                 (list (map-dll fn parameter))
                 (symbol (funcall fn type parameter)))))
      (macrolet ((parse-keyword ((&rest symbols) &body body)
                   `(progn
                      (when (and (not (atom list))
                                 (member (first list) ',symbols))
                        (save (pop list))
                        ,@body)))
                 (doparameters ((var) &body body)
                   `(do () ((or (atom list) (member (first list) keywords)))
                      (save (let ((,var (pop list)))
                              ,@body)))))
        (parse-keyword (&whole)
          (save (handle :whole (pop list))))
        (doparameters (required)
         (handle :required required))
        (parse-keyword (&optional)
         (doparameters (opt)
          (if (symbolp opt)
              (handle :optional opt)
              (list* (handle :optional (first opt)) (rest opt)))))
        (when (and (atom list) (not (null list))) ; turn (... . REST) 
          (setq list (list '&rest list)))         ; into (... &rest REST)
        (parse-keyword (&rest &body)
         (save (handle :rest (pop list))))
        (parse-keyword (&key)
         (doparameters (key)
          (if (symbolp key)
              (handle :key key)
              (destructuring-bind (keyspec . more) key
                (if (symbolp keyspec)
                    (list* (handle :key keyspec) more)
                    (destructuring-bind (keyword var) keyspec
                      (list* (list keyword (handle :key var)) more)))))))
        (parse-keyword (&allow-other-keys))
        (parse-keyword (&aux)
         (doparameters (aux) aux))
        (unless (null list)
          (error "Bad destructuring lambda list: ~A." orig))
        (nreverse result)))))

使用它,编写一个destructuring-bind*非常容易,它将用_开头的每个模式变量替换为一个在体内将被忽略的新变量.

(defmacro destructuring-bind* (lambda-list object &body body)
  (let* ((ignores '())
         (lambda-list (map-dll (lambda (type var)
                                 (declare (ignore type))
                                 (if (and (> (length (symbol-name var)) 0)
                                          (char= #\_ (char (symbol-name var) 0)))
                                     (let ((var (gensym)))
                                       (push var ignores)
                                       var)
                                     var))
                               lambda-list)))
    `(destructuring-bind ,lambda-list ,object
       (declare (ignore ,@(nreverse ignores)))
       ,@body)))

现在我们应该看看它产生的扩展:

(macroexpand-1
 '(destructuring-bind* (&whole (a _ . b)
                        c _ d
                        &optional e (f '_f)
                        &key g _h
                        &aux (_i '_j))
   object
   (list a b c d e f g)))
;=>                            
(DESTRUCTURING-BIND
    (&WHOLE (A #:G1041 &REST B) C #:G1042 D
     &OPTIONAL E (F '_F)
     &KEY G #:G1043
     &AUX (_I '_J))
    OBJECT
  (DECLARE (IGNORE #:G1041 #:G1042 #:G1043))
  (LIST A B C D E F G))

我们没有替换任何我们不应该的东西(初始形式,辅助变量等),但我们已经处理了我们应该处理的地方.我们也可以在您的示例中看到这项工作:

(macroexpand-1
 '(destructuring-bind* ((_ (_ . title)
                         (_ . description)
                         _
                         (_ . video-id)))
   entry
   (list video-id title description)))
;=>
(DESTRUCTURING-BIND ((#:G1044 (#:G1045 &REST TITLE)
                              (#:G1046 &REST DESCRIPTION)
                              #:G1047
                              (#:G1048 &REST VIDEO-ID)))
    ENTRY
  (DECLARE (IGNORE #:G1044 #:G1045 #:G1046 #:G1047 #:G1048))
  (LIST VIDEO-ID TITLE DESCRIPTION))