如何通过访问器在树中设置元素？

Question

我们在AI课程中一直使用Lisp.我收到的作业涉及搜索和生成树状结构.对于每个作业,我最终都写了类似的东西:

(defun initial-state ()
  (list 
    0    ; score
    nil  ; children
    0    ; value
    0))  ; something else

并围绕这些"状态"构建我的函数,这些状态实际上只是具有一些松散定义结构的嵌套列表.

为了使结构更加严格,我尝试编写访问器,例如:

(defun state-score ( state )
  (nth 2 state))

这适用于读取值(这应该是我在一个功能良好的世界中需要做的全部.但是,随着时间的推移,我开始疯狂地破解,有时我想要一个可变的结构).我似乎无法SETF返回...的东西(地方？值？指针？).

我得到一个类似的错误:

(setf (state-score *state*) 10)

有时我似乎有更多的运气将accessor/mutator写成宏:

(defmacro state-score ( state )
  `(nth 2 ,state))

但是我不知道为什么这应该是一个宏,所以我当然不应该把它写成一个宏(除了有时候它有效.巧合编程很糟糕).

建立这样的结构的适当策略是什么？

更重要的是,我在哪里可以了解到这里发生的事情(哪些操作以什么方式影响记忆)？

Answer 1

将CLOS用于数据结构

最好的方法是快速学习CLOS的基础知识.

(defclass state ()
  ((score    :accessor state-score    :initform 0)
   (children :accessor state-children :initform nil)
   (value    :accessor state-value    :initform 0)))

(defun make-initial-state ()
  (make-instance 'state))

(defparameter *state* (make-initial-state))

(setf (state-score *state*) 10)

对于大多数应用代码避免结构

对于大多数代码避免使用结构 - 仅在需要时使用它们并知道原因.请改用CLOS类.

DEFSTRUCT也适用于列表

如果你真的想使用列表,一个选项是使用带有列表的DEFSTRUCT宏并让它定义所有函数:

(defstruct (state (:type list))
  (score 0)
  (children nil)
  (value 0))

上面,:type选项告诉DEFSTRUCT使用列表而不是结构.

? (defparameter *state* (make-state))
*STATE*
? (setf (state-score *state*) 10)
10

(make-state)返回三个项目的列表.

我们可以编写setter函数

如果你想手工编写代码,那么你可以编写setter函数:

(defun get-my-score (state)
  (first state))

(defun (setf get-my-score) (score state)
  (setf (first state) score))

以上定义了SETF功能.该函数的名称实际上是一个列表.此函数的参数必须首先是新值,然后是要设置的事物.

? (setf *state* (list 0 nil 0))
(0 NIL 0)
? (setf (get-my-score *state*) 10)
10
? *state*
(10 NIL 0)

Common Lisp HyperSpec定义了哪些地方以及如何使用它们.我猜这不是最好的学习资源,可能最好在一些介绍性的Lisp书中解释.