DOSKEY 召回别名

Question

是否可以使用 DOSKEY 调用别名？简单的例子..我想做这样的事情：

DOSKEY a=someCommand
DOSKEY b=someOtherCommand
DOSKEY c=andAThirdCommand

:: How to do this? -> DOSKEY all=a+b+c

我已经知道我可以通过写这个来做到这一点：

DOSKEY all=someCommand ^& someOtherCommand ^& andAThirdCommand

但在重用东西的意义上，我想重用上面定义的别名。有可能如我所愿吗？

谢谢！

PS：在这里看到了这个，但这不是一个令人满意的答案。不过好像行不通。:(

Answer 1

好问题，很难回答...但是，我可以建议使用简单的批处理脚本的解决方法。

假设我们已经定义了doskey a=commandAanddoskey a=commandB和doskey c=commandC宏。

1. 静态方法：让我们将我们的脚本命名为eg （define demm acro ）并将其放置在您的path. 然后dem acb a c b应该定义一个新的宏 acb（准备进一步使用）如下：doskey acb=commandA $T commandC $T commandB。该脚本可以通过对提供的脚本进行一些修改来建立dsk（提示：不是启动宏文本，而是构成新宏的文本，但要注意另一个转义）。

2. 动态方法：让我们将脚本命名为例如dsk( d o sk ey) 并将其放置在您的path. 然后dsk a b c应该按顺序调用宏 a,b和。c传递给脚本的参数（宏名称）数量不受限制。该脚本适用于定义非常简单的宏，但是

   • 允许%使用百分号，如在doskey a=echo %variable%宏中和/或什至for在循环中使用doskey a=for /F "tokens=*" %G in ('dir /b /s *.txt') do @echo %G；
   • 允许$T在宏（相当于&批处理文件）中连接命令，例如doskey a=dir $T set; $T通过替换来完成&（在极少数情况下还不够，然后需要拆分并单独执行命令）。

已知问题和/或限制（如果不了解更多有关所用宏的实际结构，则无法解决）；剧本dsk​

• 循环for可能会带来变量问题%%parameter；否决在宏中使用：（%%{外循环）和%%? %%@（内循环）
• 不考虑管道或重定向doskey a=dir ^> somefile；
• 不允许^&宏中的串联命令（但允许doskey内在$T串联）；
• 不允许启动批处理.bat或.cmd脚本（需要call %xitem%而不是%xitem%在:doItem程序中（cca 第 50 行）；
• 如果没有找到宏名称，则它只是被跳过......

脚本dsk如下：

:: dsk.bat
@ECHO OFF >NUL
@SETLOCAL enableextensions enabledelayedexpansion
set "CheckOnly=0"

set "DoneList="
set "ToDoList="
set "xitem=x"
for %%{ in (%*) do (
  set "_G_found=0"
  echo.
  for /F "tokens=1* delims==" %%? in ('doskey /macros') do (
    if /i "%%{"=="%%?" (
      for /F "tokens=*" %%_ in ("%%@") do set "item=%%_"
      if /i "!item:~0,3!"=="for" set "item=!item:%%=%%%%!"
      if "%CheckOnly%"=="1" (
          echo :  to do: '!item!'
      ) else (
          echo :  To Do: '!item!'
          call :doItem !item!
      )
      set "DoneList=!DoneList! +%%{"
      set "_G_found=1"
    ) 
  )
  if "!_G_found!"=="0" (
    set "DoneList=!DoneList! -%%{"
    echo :  macro: [%%{] ^(not found^)
    if "!ToDoList!"=="" set "ToDoList=!ToDoList!, [%%{]"
    if "!ToDoList!"=="!ToDoList:[%%{]=!" set "ToDoList=!ToDoList!, [%%{]"
  )
)
echo.
echo :  
echo :    trailing progress report
echo :  
if "%ToDoList%"=="" (
    echo :    all found: %DoneList:~1%
) else (
    echo :    +found, -not found: %DoneList:~1%
    echo :   %ToDoList:~2% not found in macro name list 
)
echo :    end of batch %~f0
echo :  
:endlocal
@ENDLOCAL
@goto :eof

:doItem
  set "xitem=%*"
  set "xitem=%xitem:$T=&%"
  %xitem%
@goto :eof

下一个场景：

d:\bat>doskey /macros
y=for /F "tokens=*" %g in ('dir /b rand.bat') do @echo %g
x=dir /B /AD $T dir /B /AD "D:\Remote\bat\COCL\bu bu bu" $T set y
a=echo CheckOnly=%CheckOnly%
b=rand.bat

并dsk y b a x n调用给出下一个输出：

d:\bat>dsk y b a x n

:  To Do: 'for /F "tokens=*" %%g in ('dir /b rand.bat') do @echo %%g'
rand.bat

:  To Do: 'rand.bat'
The system cannot find the batch label specified - doItem

:  To Do: 'echo CheckOnly=%CheckOnly%'
CheckOnly=0

:  To Do: 'dir /B /AD $T dir /B /AD "D:\Remote\bat\COCL\bu bu bu" $T set y'
files
a.dot 1.dot 2.dot 3
Environment variable y not defined

:  macro: [n] (not found)

:
:    trailing progress report
:
:    +found, -not found: +y +b +a +x -n
:   [n] not found in macro name list
:    end of batch d:\bat\dsk.bat
:
d:\bat>

该脚本对于调试目的来说相当冗长（并且也是可变的CheckOnly，其值1=仅回显命令，0=回显并在宏中执行命令）。