如何在已打开的Delphi IDE中从另一个应用程序打开.pas文件并定位到行#

Question

假设我打开了Delphi IDE,如何打开.pas在另一个应用程序中选择的文件并在Delphi IDE中打开它,并将其定位到特定的行号？

我见过一些编辑工具可以做到这一点.

我不确定它是否只是普通文件打开的选项(例如,使用默认文件关联)或命令行选项,或者您需要DDE或COM或完全不同的东西.

请注意,我不想关闭项目并重新打开一个新的或假的项目.

另外,我不希望将文件添加到项目中.我只是想打开它.

例如,当您<ctrl>-click使用varible或type时,IDE将打开包含该符号的文件,并转到声明该符号的行.这就是我想要的 - 但是来自外部应用程序.(我不是在寻找一个符号,只是一条线.)

我目前正在使用Delphi XE5,所以我对新的Delphi版本感兴趣,而不是XE2之前的版本.

(部分问题是,如何确保IDE已经打开,该文件是在当前IDE内部的新选项卡中打开而不是在IDE的另一个实例中打开的？)

Answer 1

下面的代码（针对 D7）显示了如何通过编译为 Bpl 的 IDE 插件 .Dpk 来完成此操作。它一开始只是一个“概念证明”，但它确实有效。

它包含一个“发送器”应用程序，该应用程序使用 WM_COPYDATA 将文件名、行号和列发送到 .Bpl 文件中托管的接收器。

发送者向接收者发送一个字符串，例如

Filename=d:\aaad7\ota\dskfilesu.pas
Line=8
Col=12
Comment=(* some comment or other*)

注释行是可选的。

在 .Bpl 中，接收者使用 OTA 服务打开请求的文件并定位编辑器插入符号，然后插入注释（如果有）。

最棘手的事情是找出如何处理一种特定的复杂情况，即要打开的命名文件具有关联表单的情况。如果是这样，在 D7（以及我假设启用了浮动设计器选项的其他 IDE 版本）中，当 IDE 打开 .Pas 文件时，它还会打开 .Dfm，并留给其自己的设备，这将离开表单编辑器在代码编辑器前面。为 .Pas 文件调用 IOTASourceEditor.Show 至少将 IDE 代码编辑器放在 .Dfm 表单前面，但这并不能满足我，因为现在我的好奇心被激起了 - 如何获得 IDE 的表单显示在屏幕之外？

我花了很多时间探索各种死胡同，因为 OTA + NTA 服务似乎没有提供任何方法来显式关闭 IOTAEditor 或其任何后代。最后事实证明，要做的事情只是获取对表单的引用，然后向其发送 WM_CLOSE(!) - 请参阅代码中的注释。

Fwiw，作为 OTA 的新手，一开始（在我发现 IOTAModules 的工作原理之前），我发现最困难的部分是发现如何获取设置编辑器插入符位置所需的 IEditView 界面，但是像往常一样，对于这些界面事物，一旦你完全正确地掌握了“魔法咒语”，一切都会起作用。

祝你好运！感谢您的精彩挑战！

unit Receiveru;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, ToolsAPI;

type
  TOTAEditPosnForm = class(TForm)
    Memo1: TMemo;
  private
    FEdLine: Integer;
    FEdCol: Integer;
    FEditorFileName: String;
    FEditorInsert: String;
    procedure WMCopyData(var Msg : TWMCopyData); message WM_COPYDATA;
    procedure HandleCopyDataString(CopyDataStruct : PCopyDataStruct);
    procedure OpenInIDEEditor;
    property EditorFileName : String read FEditorFileName write FEditorFileName;
    property EdLine : Integer read FEdLine write FEdLine;
    property EdCol : Integer read FEdCol write FEdCol;
    property EditorInsert : String read FEditorInsert write FEditorInsert;
  end;

var
  OTAEditPosnForm: TOTAEditPosnForm;

procedure Register;

implementation

{$R *.dfm}

procedure MonitorFiles;
begin
  OTAEditPosnForm := TOTAEditPosnForm.Create(Nil);
  OTAEditPosnForm.Show;
end;

procedure Register;
begin
  MonitorFiles;
end;

procedure TOTAEditPosnForm.OpenInIDEEditor;
var
  IServices : IOTAServices;
  IActionServices : IOTAActionServices;
  IModuleServices : IOTAModuleServices;
  IEditorServices : IOTAEditorServices60;
  IModule : IOTAModule;
  i : Integer;
  IEditor : IOTAEditor;
  ISourceEditor : IOTASourceEditor;
  IFormEditor : IOTAFormEditor;
  IComponent : IOTAComponent;
  INTAComp : INTAComponent;
  AForm : TForm;
  IEditView : IOTAEditView;
  CursorPos : TOTAEditPos;
  IEditWriter : IOTAEditWriter;
  CharPos : TOTACharPos;
  InsertPos : Longint;
  FileName : String;
begin
  IServices := BorlandIDEServices as IOTAServices;
  Assert(Assigned(IServices), 'IOTAServices not available');

  IServices.QueryInterface(IOTAACtionServices, IActionServices);
  if IActionServices <> Nil then begin

    IServices.QueryInterface(IOTAModuleServices, IModuleServices);
    Assert(IModuleServices <> Nil);

    //  Close all files open in the IDE
    IModuleServices.CloseAll;

    if IActionServices.OpenFile(EditorFileName) then begin

      //  At this point, if the named file has an associated .DFM and
      //  we stopped here, the form designer would be in front of the
      //  code editor.

      IModule := IModuleServices.Modules[0];
      //  IModule is the one holding our .Pas file and its .Dfm, if any
      //  So, iterate the IModule's editors until we find the one
      //  for the .Pas file and then call .Show on it.  This will
      //  bring the code editor in front of the form editor.

      ISourceEditor := Nil;

      for i := 0 to IModule.ModuleFileCount - 1 do begin
        IEditor := IModule.ModuleFileEditors[i];
        FileName := IEditor.FileName;
        Memo1.Lines.Add(Format('%d %s', [i, FileName]));
        if CompareText(ExtractFileExt(IEditor.FileName), '.Pas') = 0 then begin
          if ISourceEditor = Nil then begin
            IEditor.QueryInterface(IOTASourceEditor, ISourceEditor);
            IEditor.Show;
          end
        end
        else begin
          // Maybe the editor is a Form Editor.  If it is
          // close the form (the counterpart to the .Pas, that is}
          IEditor.QueryInterface(IOTAFormEditor, IFormEditor);
          if IFormEditor <> Nil then begin
            IComponent := IFormEditor.GetRootComponent;
            IComponent.QueryInterface(INTAComponent, INTAComp);
            AForm := TForm(INTAComp.GetComponent);
            //AForm.Close; < this does NOT close the on-screen form
            // IActionServices.CloseFile(IEditor.FileName); <- neither does this
            SendMessage(AForm.Handle, WM_Close, 0, 0);  // But this does !
          end;
        end;
      end;

      //  Next, place the editor caret where we want it ...
      IServices.QueryInterface(IOTAEditorServices, IEditorServices);
      Assert(IEditorServices <> Nil);

      IEditView := IEditorServices.TopView;
      Assert(IEditView <> Nil);
      CursorPos.Line := edLine;
      CursorPos.Col := edCol;
      IEditView.SetCursorPos(CursorPos);
      //  and scroll the IEditView to the caret
      IEditView.MoveViewToCursor;

      //  Finally, insert the comment, if any
      if EditorInsert <> '' then begin
        Assert(ISourceEditor <> Nil);
        IEditView.ConvertPos(True, CursorPos, CharPos);
        InsertPos := IEditView.CharPosToPos(CharPos);
        IEditWriter := ISourceEditor.CreateUndoableWriter;
        Assert(IEditWriter <> Nil, 'IEditWriter');
        IEditWriter.CopyTo(InsertPos);
        IEditWriter.Insert(PChar(EditorInsert));
        IEditWriter := Nil;
      end;
    end;
  end;
end;

procedure TOTAEditPosnForm.HandleCopyDataString(
  CopyDataStruct: PCopyDataStruct);
begin
  Memo1.Lines.Text := PChar(CopyDataStruct.lpData);

  EditorFileName := Memo1.Lines.Values['FileName'];
  edLine := StrToInt(Memo1.Lines.Values['Line']);
  edCol := StrToInt(Memo1.Lines.Values['Col']);
  EditorInsert := Trim(Memo1.Lines.Values['Comment']);
  if EditorFileName <> '' then
    OpenInIDEEditor;
end;

procedure TOTAEditPosnForm.WMCopyData(var Msg: TWMCopyData);
begin
  HandleCopyDataString(Msg.CopyDataStruct);
  msg.Result := Length(Memo1.Lines.Text);
end;

initialization

finalization
  if Assigned(OTAEditPosnForm) then begin
    OTAEditPosnForm.Close;
    FreeAndNil(OTAEditPosnForm);
  end;
end.

发件人代码：

procedure TSenderMainForm.btnSendClick(Sender: TObject);
begin
  SendMemo;
end;

procedure TSenderMainForm.SendData(
  CopyDataStruct: TCopyDataStruct);
var
  HReceiver : THandle;
  Res : integer;
begin
  HReceiver := FindWindow(PChar('TOTAEditPosnForm'),PChar('OTAEditPosnForm'));
  if HReceiver = 0 then begin
    Caption := 'CopyData Receiver NOT found!';
  end
  else begin
    Res := SendMessage(HReceiver, WM_COPYDATA, Integer(Handle), Integer(@CopyDataStruct));
    if Res > 0 then
      Caption := Format('Received %d characters', [Res]);
  end;
end;

procedure TSenderMainForm.SendMemo;
var
  MS : TMemoryStream;
  CopyDataStruct : TCopyDataStruct;
  S : String;
begin
  MS := TMemoryStream.Create;
  try
    S := Memo1.Lines.Text + #0;
    MS.Write(S[1], Length(S));
    CopyDataStruct.dwData := 1;
    CopyDataStruct.cbData := MS.Size;
    CopyDataStruct.lpData := MS.Memory;
    SendData(CopyDataStruct);
  finally
    MS.Free;
  end;
end;