如何让tab只显示文件名而不是vim中的完整路径

Question

如果文件的完整路径很长,则无法分辨给定选项卡中的文件.所以我想知道是否有一种方法让tab只显示文件名而不是文件的完整路径,在某些情况下可能很方便.需要你的帮助,谢谢你提前.

Answer 1

尝试

:set guitablabel=%t

有关可能选项的格式,请参阅

:help'statusline'

Answer 2

我的vimrc中有以下内容:

set guitablabel=\[%N\]\ %t\ %M 

输出:[Number]文件名和+符号,如果文件被修改([4] foo.html +).使用命令[Number] gt立即切换到所选选项卡非常有用(如果我想跳转到选项卡4中的文件,则为4gt)

Answer 3

我使用此解决方案而不是 Habi 的解决方案，因为该解决方案仍然保留在选项卡中放置“+”符号以指示正在修改的文件的默认功能，以及选项卡中窗口数量的计数。所以它的工作原理与默认标签标签基本相同，但只使用文件名，而不是完整路径。

" Tab headings
function GuiTabLabel()
    let label = ''
    let bufnrlist = tabpagebuflist(v:lnum)

    " Add '+' if one of the buffers in the tab page is modified
    for bufnr in bufnrlist
        if getbufvar(bufnr, "&modified")
            let label = '+'
            break
        endif
    endfor

    " Append the number of windows in the tab page if more than one
    let wincount = tabpagewinnr(v:lnum, '$')
    if wincount > 1
        let label .= wincount
    endif
    if label != ''
        let label .= ' '
    endif

    " Append the buffer name (not full path)
    return label . "%t"
endfunction

set guitablabel=%!GuiTabLabel()