如何制作热键钩子？"背景热键"

Question

如何将热键挂钩到我的应用程序,以便,例如,如果我按CTRL+ F2它显示消息"hello world",即使应用程序被最小化或在其他应用程序上工作等？请告诉我示例或来源.

Answer 1

一种选择是使用RegisterHotKey().

此方法将向Windows注册热键或热键组合.当您的应用程序正在运行时,如果按下此热键组合,系统将通知它.要对此通知执行操作,您需要捕获WM_HOTKEY附加到您注册热键的句柄的窗口过程中的消息.

实现此目的的最简单且最不容易出错的方法是使用创建专用句柄AllocateHWND.我在这里使用了一个表单作为示例,但这也可以应用于非窗口类:

  TForm1 = class(TForm)
  private
    FHotkeyWnd : HWND;
    procedure HandleHotkey(var msg : TMessage);
  public
    constructor Create(AOwner : TComponent); override;
    destructor Destroy; override;     
  end;

您可以实现为:

const
  HOTKEY1_ID = 1;

constructor TForm1.Create(AOwner:TComponent);
begin
  inherited Create(AOwner);
  FHotkeyWnd := AllocateHWND(HandleHotkey);
  RegisterHotKey(FHotkeyWnd, HOTKEY1_ID, MOD_CONTROL, VK_F2);
end;

destructor TForm1.Destroy;
begin
  UnregisterHotKey(FHotkeyWnd, HOTKEY1_ID);
  DeallocateHWND(FHotkeyWnd);
  inherited;
end;

procedure TForm1.HandleHotkey(var msg: TMessage);
begin
  if msg.Msg = WM_HOTKEY then begin
    ShowMessage('hello world')
  else
    Msg.Result := DefWindowProc(FHotkeyWnd, msg.Msg, msg.wParam, msg.lParam);
end;

• 注意事项

请记住,对于UIPI有效的现代版Windows(Vista,7,8 ...),当提升的应用程序(相对于您的应用程序)处于活动状态时,注册的热键不会触发.例如,如果您的应用程序作为用户级应用程序运行,并且登录用户当前正在升级(即:管理员权限)应用程序中工作,那么您将不会收到热键通知.这是一项重要的安全措施,可防止较高权限的应用程序将信息泄露给较低权限的应用程序. 例.

如果这对您来说是一个重要的考虑因素,那么就有办法解决这个问题.最简单的方法是简单地为您的应用程序强制管理员权限.这显然不是最好的答案.替代方案涉及更多,需要authenticode签署您的应用程序,并且超出了本答案的范围.