使用Parsec对引用字符串进行解析

Question

我想像这样解析输入字符串: "this is \"test \" message \"sample\" text"

现在,我编写了一个解析器来解析单个文本而没有任何引号:

parseString :: Parser String
parseString = do
  char '"'
  x <- (many $ noneOf "\"")
  char '"'
  return x

这解析简单的字符串,如下所示: "test message"

然后我为引用的字符串编写了一个解析器:

quotedString :: Parser String
quotedString = do
  initial <- string "\\\""
  x <- many $ noneOf "\\\"" 
  end <- string "\\\""
  return $ initial ++ x ++ end

这个解析器的字符串是这样的: \"test message\"

有没有办法可以将两个解析器结合起来,以便获得我想要的目标？究竟解决这个问题的方法究竟是什么？

Answer 1

这就是我要做的:

escape :: Parser String
escape = do
    d <- char '\\'
    c <- oneOf "\\\"0nrvtbf" -- all the characters which can be escaped
    return [d, c]

nonEscape :: Parser Char
nonEscape = noneOf "\\\"\0\n\r\v\t\b\f"

character :: Parser String
character = fmap return nonEscape <|> escape

parseString :: Parser String
parseString = do
    char '"'
    strings <- many character
    char '"'
    return $ concat strings

现在您需要做的就是调用它:

parse parseString "test" "\"this is \\\"test \\\" message \\\"sample\\\" text\""

Parser组合器起初有点难以理解,但是一旦掌握了它,它们就比编写BNF语法更容易.