在ANTLR中,如何指定特定的重复次数？

Question

我正在使用ANTLR指定包含不超过254个字符的行的文件格式(不包括行结尾).如何在语法中对此进行编码,但不做:

line : CHAR? CHAR? CHAR? CHAR? ... (254 times)

Answer 1

这可以通过使用语义谓词来处理.

首先写下你的语法,使你的线条无关紧要.一个例子看起来像这样:

grammar Test;

parse
  :  line* EOF
  ;

line
  :  Char+ (LineBreak | EOF)
  |  LineBreak // empty line!
  ;

LineBreak : '\r'? '\n' | '\r' ;
Char      : ~('\r' | '\n') ;

然后将"谓词"添加到line规则中:

grammar Test;

@parser::members {
    public static void main(String[] args) throws Exception {
        String source = "abcde\nfghij\nklm\nnopqrst";
        ANTLRStringStream in = new ANTLRStringStream(source);
        TestLexer lexer = new TestLexer(in);
        CommonTokenStream tokens = new CommonTokenStream(lexer);
        TestParser parser = new TestParser(tokens);
        parser.parse();
    }  
}

parse
  :  line* EOF
  ;

line
  :  (c+=Char)+ {$c.size()<=5}? (LineBreak | EOF)
  |  LineBreak // empty line!
  ;

LineBreak : '\r'? '\n' | '\r' ;
Char      : ~('\r' | '\n') ;

在c+=Char将构建一个ArrayList包含在该行的所有字符.{$c.size()<=5}?当ArrayList大小超过5 时抛出异常的原因.

我还在解析器中添加了一个main方法,以便您自己测试它:

// *nix/MacOSX
java -cp antlr-3.2.jar org.antlr.Tool Test.g
javac -cp antlr-3.2.jar *.java
java -cp .:antlr-3.2.jar TestParser

// Windows
java -cp antlr-3.2.jar org.antlr.Tool Test.g
javac -cp antlr-3.2.jar *.java
java -cp .;antlr-3.2.jar TestParser

这将输出:

line 0:-1 rule line failed predicate: {$c.size()<=5}?

HTH