批量收集到表类型的对象中

Question

尝试使用对象表的BULK COLLECT语句时出错ORA-00947: not enough values。

线路发生错误 from (select jta.nobject_id,

CREATE OR REPLACE TYPE "T_PPW_WORK"  as object                                     
    (          
      nObjectKey   number,  
      cJobType     varchar2(500),  
      dPlanStart   date,
      dPlanEnd     date,
      cExecutor    varchar2(500),
      cComment     varchar2(4000)
    )

    CREATE OR REPLACE TYPE "T_PPW_WORK_TABLE" as table of T_PPW_WORK;                                         


      function getPlannedOverdueJobs(in_nPlanKey number) return T_PPW_WORK_TABLE is
        l_oWorks T_PPW_WORK_TABLE;    
        l_oWork T_PPW_WORK;    
      begin

        select * bulk collect
          into l_oWorks
          from (select jta.nobject_id,
                       jt.cjobtype_name,                           
                       jta.dactual_start,
                       jta.dactual_finish,
                       st.familiya,
                       jta.ccomment
                  from ppw_jobtype_assign jta
                  left join pgts_sotrudnik st
                    on jta.nworkerid = st.npgts_sotrudnikkey
                  join ppw_jobtype jt
                    on jta.njobtype_id = jt.njobtype_key);
        return l_oWorks;
      end getPlannedOverdueJobs;

是什么原因？

Answer 1

    select * bulk collect
      into l_oWorks
      from (select t_ppw_work(jta.nobject_id,
                   jt.cjobtype_name,                           
                   jta.dactual_start,
                   jta.dactual_finish,
                   st.familiya,
                   jta.ccomment)
              from ppw_jobtype_assign jta
              left join pgts_sotrudnik st
                on jta.nworkerid = st.npgts_sotrudnikkey
              join ppw_jobtype jt
                on jta.njobtype_id = jt.njobtype_key);

您需要先使用定义的对象类型 (t_ppw_work) 转换结果集。