在Perl脚本中分离配置数据和脚本逻辑

Question

我发现在我的Perl脚本中重复了以下反模式:脚本包含一些特定于机器/设置的设置,我将其作为常量存储在脚本中,而脚本的其余部分本质上是通用的:

#!/usr/bin/perl

use strict;
use warnings;

# machine specific settings at the start of the script.
my $SETTING_1 = "foo";
my @SETTING_2 = ("123", "456");
my $SETTING_3 = "something";

# general part of script follows.
...

在一台机器上运行时,这种模式有点好,但是一旦我想将脚本分发到多台机器上就会出现问题,因为我必须跟踪,因此我不会在常规部分中使用新的更新覆盖设置部分.

正确的解决方案显然是拥有一个通用脚本文件,并让它读取一个特定于脚本运行环境的配置文件.

我的问题是:您建议使用哪种CPAN模块来解决此问题？为什么？

Answer 1

对于配置文件,我喜欢使用YAML.简单,跨平台,人类可读,并且没有您的配置意外变形为实际程序的危险.

Answer 2

我最喜欢的是Config::Std。我喜欢它处理多行和多部分配置值的方式。

当变量可能是多值时，您必须小心：如果配置文件中存在单个值，它将将该值存储在标量中；如果存在多个值，您将获得一个数组引用。

我发现有两个配置文件很方便：一个用于描述操作环境的值（在哪里可以找到库等），另一个用于用户可修改的行为。

我也喜欢围绕它写一个包装。例如（更新为包括自动生成的只读访问器）：

#!/usr/bin/perl

package My::Config;
use strict; use warnings;

use Config::Std;
use FindBin qw($Bin);
use File::Spec::Functions qw( catfile );

sub new {
    my $class = shift;
    my ($config_file) = @_;

    $config_file = catfile($Bin, 'config.ini');
    read_config $config_file => my %config;

    my $object = bless \%config => $class;

    $object->gen_accessors(
        single => {
            install => [ qw( root ) ],
        },
        multi => {
            template => [ qw( dir ) ],
        },
    );

    return $object;
}

sub gen_accessors {
    my $config = shift;
    my %args = @_;

    my $class = ref $config;

    {
        no strict 'refs';
        for my $section ( keys %{ $args{single} } ) {
            my @vars = @{ $args{single}->{$section} };
            for my $var ( @vars ) {
                *{ "${class}::${section}_${var}" } = sub {
                    $config->{$section}{$var};
                };
            }
        }

        for my $section ( keys %{ $args{multi} } ) {
            my @vars = @{ $args{multi}->{$section} };
            for my $var ( @vars ) {
                *{ "${class}::${section}_${var}" } = sub {
                    my $val = $config->{$section}{$var};
                    return [ $val ] unless 'ARRAY' eq ref $val;
                    return $val;
                }
            }
        }
    }

    return;
}

package main;

use strict; use warnings;

my $config = My::Config->new;

use Data::Dumper;
print Dumper($config->install_root, $config->template_dir);

C:\Temp> cat config.ini
[安装]
根= c:\opt

[模板]
目录 = C:\opt\app\tmpl
目录 = C:\opt\common\tmpl

输出：

C:\Temp> g.pl
$VAR1 = 'c:\\opt';
$VAR2 = [
          'C:\\opt\\app\\tmpl',
          'C:\\opt\\common\\tmpl'
        ];