$ _的范围:为什么会改变它？

Question

我有一个如下代码片段:

use strict;
use warnings;

# file names to search for
open(my $files,  "<",  "fileList.txt") or die "Can't open fileList.txt: $!";

my $flag = 0;
while (<$files>) {
    print "File loop: $_\n";

    open(my $search,  "<",  "searchMe.txt") or die "Can't open searchMe.txt: $!";

    $flag = 0;
    while (<$search>){
        print "Search loop: $_\n";
    }
}

fileList.txt包含一行:"CheckFilesFunctions.pm"

searchMe.txt包含一行:abc

这里的输出是

File loop: CheckFilesFunctions.pm
Search loop: abc

然而.当我将搜索循环更改为以下内容时

while (<$search> && !$flag){

突然,搜索循环开始打印

Search loop: CheckFilesFunctions.pm

为什么$ _的范围在这里变化？

Answer 1

while (<filehandle>)是便捷的简写while (defined( $_ = <filehandle> )); 如果你有一个更复杂的表达式来测试,你需要明确包含完整的东西:

while ( defined( $_ = <$search> ) && ! $flag ) {

虽然我建议明确使用readline(<>可以表示readline或者glob,取决于参数;我更喜欢直接使用它们)并使用词法变量:

while ( defined( my $line = readline $search ) && ! $flag ) {

或者,您可以突破循环而不是修改条件:

while (<$search>) {
    ...
    if (...) {
        last;

通过查看代码,您可能希望在文件循环之前只将一次搜索文件读入数组,然后循环遍历该数组.