如何在excel 2007中执行两个二进制数的XOR计算

Question

我想对两个二进制数进行XOR计算,例如:在Sheet 1上

Range A1 = 10101010
Range A2 = 11100010

现在我需要执行A1的A1,A2的结果.我尝试了不同的公式,两个执行XOR计算,如:A1^A2, (BITXOR (A1, A2))但不幸的是它没有用,我认为因为我使用excel 2007"XOR"不支持.

我期待着结果1001000.

Answer 1

首先,您应该注意Excel pre-Excel2013没有内置的按位运算符或函数(即使操作数是数字,Excel的OR()函数也是合乎逻辑的).Excel 2013最终添加了这个明显缺失的功能.

使用VBA

最简单的方法是创建一个用户定义函数来完成它.如果您准备好十进制输出或辅助列,或者非常重复的Concatenate公式,但VBA可以解决这些限制,公式可以工作 - 如果您能够在工作簿中使用代码,我建议使用它.

十进制输入,十进制输出

下面的示例仅显示内置的按位运算符,以用作Excel公式中的函数.我假设一个整数类型,虽然您可以将其更改为接受小数等.

您可以使用Excel内置的BIN2DEC()函数将您的字符串二进制数(例如"1010")转换为小数(10,对于前一个示例),尽管这只能处理9位+符号位,或者您可以使用数组公式为您转换它(请参阅下面的"使用公式"部分).

Public Function BITWISE_OR(operand1, operand2)
   BITWISE_OR = CLng(operand1) Or CLng(operand2)
End Function
Public Function BITWISE_AND(operand1, operand2)
   BITWISE_AND = CLng(operand1) And CLng(operand2)
End Function
Public Function BITWISE_XOR(operand1, operand2)
   BITWISE_XOR = CLng(operand1) Xor CLng(operand2)
End Function

将数值结果转换回二进制字符串对于公式来说非常烦人 - 如果你需要超过DEC2BIN()(微不足道的-512到+511)函数覆盖的范围,那么我会建议使用VBA(见下文) ),或使用列或行逐位构建二进制字符串(请参阅下面的"使用公式"部分).

二进制字符串输入,二进制字符串输出

下面基本上根据输入字符串中的相应位依次遍历字符串设置每个位.它使用Mid$语句就地对字符串执行位更改.位串可以是任意长度.

下面看起来很复杂,但实际上它是And,Or和XOr每次重复3次相同的基本内容.

'str1, str2: the two bit strings. They can be different lengths.
'significantDigitsAreLeft: optional parameter to dictate how different length strings should be padded. Default = True.
Public Function Bitstr_AND(str1 As String, str2 As String, Optional significantDigitsAreLeft As Boolean = True)
    Dim maxLen As Long, resStr As String, i As Long
    If Len(str1) > Len(str2) Then maxLen = Len(str1) Else maxLen = Len(str2) 'get max length of the two strings
    str1 = getPaddedString(str1, maxLen, significantDigitsAreLeft) 'pad left or right to the desired length
    str2 = getPaddedString(str2, maxLen, significantDigitsAreLeft) 'pad left or right to the desired length
    resStr = String$(maxLen, "0") 'prepare the result string into memory (Mid$ can operate without creating a new string, for performance)
    For i = 1 To maxLen
        If Mid$(str1, i, 1) = "1" And Mid$(str2, i, 1) = "1" Then
            Mid$(resStr, i, 1) = "1" 'in-place overwrite of the existing "0" with "1"
        End If
    Next i
    Bitstr_AND = resStr
End Function
'For explanatory comments, see Bitstr_AND
Public Function Bitstr_OR(str1 As String, str2 As String, Optional significantDigitsAreLeft As Boolean = True)
    Dim maxLen As Long
    Dim resStr As String
    Dim i As Long
    If Len(str1) > Len(str2) Then maxLen = Len(str1) Else maxLen = Len(str2)
    str1 = getPaddedString(str1, maxLen, significantDigitsAreLeft)
    str2 = getPaddedString(str2, maxLen, significantDigitsAreLeft)
    resStr = String$(maxLen, "0")
    For i = 1 To maxLen
        If Mid$(str1, i, 1) = "1" Or Mid$(str2, i, 1) = "1" Then
            Mid$(resStr, i, 1) = "1"
        End If
    Next i
    Bitstr_OR = resStr
End Function
'For explanatory comments, see Bitstr_AND
Public Function Bitstr_XOR(str1 As String, str2 As String, Optional significantDigitsAreLeft As Boolean = True)
    Dim maxLen As Long
    Dim resStr As String
    Dim i As Long
    If Len(str1) > Len(str2) Then maxLen = Len(str1) Else maxLen = Len(str2)
    str1 = getPaddedString(str1, maxLen, significantDigitsAreLeft)
    str2 = getPaddedString(str2, maxLen, significantDigitsAreLeft)
    resStr = String$(maxLen, "0")
    For i = 1 To maxLen
        If Mid$(str1, i, 1) = "1" Then
            If Not Mid$(str2, i, 1) = "1" Then
                Mid$(resStr, i, 1) = "1"
            End If
        ElseIf Mid$(str2, i, 1) = "1" Then 'Save an If check by assuming input string contains only "0" or "1"
            Mid$(resStr, i, 1) = "1"
        End If
    Next i
    Bitstr_XOR = resStr
End Function
'Helper to pad string
Private Function getPaddedString(str As String, length As Long, padLeft As Boolean) As String
    If Len(str) < length Then
        If padLeft Then
            getPaddedString = String$(length - Len(str), "0") & str
        Else
            getPaddedString = str & String$(length - Len(str), "0")
        End If
    Else
        getPaddedString = str
    End If
End Function

使用公式

您可以使用文本函数或Sumproduct执行XOR运算.如果您不想使用VBA,这可能更合适,但公式很难确保它们涵盖所有情况,例如否定或不同长度的二进制字符串.我将推荐您使用Sumproduct和http://chandoo.org/wp上的精彩博客文章http://www.excelhero.com/blog/2010/01/5-and-3-is-1.html / 2011/07/29/bitwise-operations-in-excel /使用文本函数的示例.

我制作了自己的公式来处理某些情况,我在下面解释它们来指导你.

二进制字符串输入,十进制输出

在下面,A2和B2指的是最多32位字符串形式的两个二进制数.字符串可以是可变长度,因为公式将填充0到必要的长度.显而易见的是如何将其增加到更多位.他们必须用Ctrl + Shift + Enter键输入.

最重要的位在左侧.为了使它在左边的最低位,你可以删除2部分的幂的小减法,并使其填充到右边.

按位和:

=SUM((((MID(REPT("0",32-LEN($A$2))&$A$2,ROW($1:$32),1)="1")+(MID(REPT("0",32-LEN($B$2))&$B$2,ROW($1:$32),1)="1"))=2)*(2^(32-ROW($1:$32))))

按位或:

=SUM((((MID(REPT("0",32-LEN($A$2))&$A$2,ROW($1:$32),1)="1")+(MID(REPT("0",32-LEN($B$2))&$B$2,ROW($1:$32),1)="1"))>0)*(2^(32-ROW($1:$32))))

Bitwise Xor:

=SUM((((MID(REPT("0",32-LEN($A$2))&$A$2,ROW($1:$32),1)="1")+(MID(REPT("0",32-LEN($B$2))&$B$2,ROW($1:$32),1)="1"))=1)*(2^(32-ROW($1:$32))))

二进制字符串输入,二进制字符串输出

单个单元格解决方案将是艰巨的,因为Excel中没有数组连接公式.您可以使用CONCATENATE函数将每个位粘合在一起,每个位都是If的结果,If比较每个返回1或0的二进制字符串.正如我所说,虽然容易(只是建立起来像= IF(中(A1,1,1)="1",...),这将是无聊所以我个人不会为你做;)

或者,您可以更简单地使用列或行来构建字符串,例如:如果A1和B1具有二进制字符串,则在C1中放置(对于AND,或者对于OR,将末尾的= 2更改为> 0)并且对于XOR,将其更改为= 1):

=IF((MID($A1,1,1)="1")+(MID($B1,1,1)="1"))=2, "1", "0")

然后在D1中放:

=C1 & IF((MID($A1,COLUMN()-COLUMN($C1),1)="1")+(MID($B1,COLUMN()-COLUMN($C1),1)="1"))=2,"1","0")

然后将它拖过尽可能多的列作为位