复选框,用于Excel中单个单元格中的多个值

Question

复选框,用于Excel中单个单元格中的多个值

may*_*lle 6 excel vba excel-2007 excel-vba

我是一名C#/ .NET开发人员,但对Excel编程或VBA不太熟悉.对于辅助项目,我有一个电子表格,非技术用户将使用该电子表格进行数据输入.稍后,这个电子表格将通过我编写的C#命令行程序导出为不同的格式,以便可以将数据转储到不同的系统中.

我需要准确输入数据值,就像命令行程序所期望的那样,因此由于拼写错误或轻微的措辞差异而导致的用户错误将是有问题的.我需要用户从可能的值中进行选择,而不是依赖于用户输入正确的值.

对于只能在单元格中具有单个值的列,我可以通过使用用户可以选择的下拉菜单来完成此操作.我是通过这里的说明做到的:

http://office.microsoft.com/en-us/excel-help/insert-or-delete-a-drop-down-list-HP010072599.aspx

问题是,我有几个列,其单元格可以包含多个值,以逗号分隔.例如,我有一个"颜色"列.该列中的单元格的值可以是单色(例如"红色")或由逗号分隔的颜色列表(例如"红色,绿色,蓝色").理想情况下,我希望用户能够单击单元格并查看复选框列表,从中可以选择颜色,完成后,单元格将使用逗号分隔的颜色进行更新.

完成此任务的最佳方法是什么？我试过谷歌搜索,发现这个方法:

http://www.contextures.com/excel-data-validation-multiple.html

...允许从下拉菜单中选择多个项目,但这很不方便,因为每次需要添加其他项目时都必须重新打开下拉列表.复选框会更方便.这是可能的,如果是的话,怎么样？

Answer 1

L42*_*L42 7

试试这个:

Option Explicit
Dim fillRng As Range
Private Sub Worksheet_SelectionChange(ByVal Target As Range)

Dim LBColors As MSForms.ListBox
Dim LBobj As OLEObject
Dim i As Long

Set LBobj = Me.OLEObjects("LB_Colors")
Set LBColors = LBobj.Object

    If Not Intersect(Target, [B2]) Is Nothing Then
        Set fillRng = Target
        With LBobj
            .Left = fillRng.Left
            .Top = fillRng.Top
            .Width = fillRng.Width
            .Visible = True
        End With
    Else
        LBobj.Visible = False
        If Not fillRng Is Nothing Then
            fillRng.ClearContents
            With LBColors
                If .ListCount <> 0 Then
                    For i = 0 To .ListCount - 1
                        If fillRng.Value = "" Then
                            If .Selected(i) Then fillRng.Value = .List(i)
                        Else
                            If .Selected(i) Then fillRng.Value = _
                                fillRng.Value & "," & .List(i)
                        End If
                    Next
                End If
                For i = 0 To .ListCount - 1
                    .Selected(i) = False
                Next
            End With
            Set fillRng = Nothing
        End If
    End If

End Sub

Run Code Online (Sandbox Code Playgroud)

在上面的代码中,我使用的OleObject所述的MsForm.Listbox类型.
首先设置你的Listbox OleObject,这是在这里讨论的.
在上面的代码中,我将my命名Listbox为LB_Colors可以通过访问其属性来更改.

假设您设置了如下数据:

在此输入图像描述