Delphi - 在OSX上获得完整堆栈跟踪

Question

我有一个可以记录堆栈跟踪的应用程序,以后可以用于调试.

在Windows上,我使用了JEDI项目提供的优秀JCLDebug单元.

现在我的应用程序在OSX上运行,我遇到了一些麻烦 - 我不知道如何在发生异常时获得正确的堆栈跟踪.

我已经掌握了基础知识 -

1)我可以使用'backtrace'获取堆栈跟踪(在libSystem.dylib中找到)

2)使用Delphi链接器提供的.map文件,可以将生成的回溯转换为行号

我留下的问题是 - 我不知道从哪里调用backtrace.我知道Delphi使用Mach异常(在一个单独的线程上),并且我不能使用posix信号,但这就是我设法解决的问题.

我可以在'try ... except'块中获得回溯,但不幸的是,到那时堆栈已经缩小了.

如何安装适当的异常记录器,它将在异常发生后立即运行？

更新:

根据'Honza R的建议,我看了一下'GetExceptionStackInfoProc'程序.

这个函数确实让我"处理"了异常处理过程,但遗憾的是,这让我遇到了一些与之前相同的问题.

首先 - 在桌面平台上,此函数'GetExceptionStackInfoProc'只是一个函数指针,您可以使用自己的异常信息处理程序进行分配.因此开箱即用,Delphi不提供任何堆栈信息提供程序.

如果我将一个函数分配给'GetExceptionStackInfoProc'然后在其中运行'backtrace',我会收到一个堆栈跟踪,但该跟踪是相对于异常处理程序的,而不是导致该异常的线程.

'GetExceptionStackInfoProc'确实包含一个指向'TExceptionRecord'的指针,但是关于这个的文档非常有限.

我可能会超越自己的深度,但是如何从正确的线程获得堆栈跟踪？我可以将自己的'backtrace'函数注入异常处理程序,然后从那里返回标准异常处理程序吗？

更新2

更多细节.要澄清一件事 - 这个问题是由MACH消息处理的异常,而不是完全在RTL中处理的软件异常.

Embarcadero已经提出了一些评论以及这些功能 -

    System.Internal.MachExceptions.pas -> catch_exception_raise_state_identity

    {
     Now we set up the thread state for the faulting thread so that when we
     return, control will be passed to the exception dispatcher on that thread,
     and this POSIX thread will continue watching for Mach exception messages.
     See the documentation at <code>DispatchMachException()</code> for more
     detail on the parameters loaded in EAX, EDX, and ECX.
    }

    System.Internal.ExcUtils.pas -> SignalConverter

    {
      Here's the tricky part.  We arrived here directly by virtue of our
      signal handler tweaking the execution context with our address.  That
      means there's no return address on the stack.  The unwinder needs to
      have a return address so that it can unwind past this function when
      we raise the Delphi exception.  We will use the faulting instruction
      pointer as a fake return address.  Because of the fencepost conditions
      in the Delphi unwinder, we need to have an address that is strictly
      greater than the actual faulting instruction, so we increment that
      address by one.  This may be in the middle of an instruction, but we
      don't care, because we will never be returning to that address.
      Finally, the way that we get this address onto the stack is important.
      The compiler will generate unwind information for SignalConverter that
      will attempt to undo any stack modifications that are made by this
      function when unwinding past it.  In this particular case, we don't want
      that to happen, so we use some assembly language tricks to get around
      the compiler noticing the stack modification.
    }

这似乎是我所面临的问题的原因.

当我在这个异常系统将控制权移交给RTL之后进行堆栈跟踪时,它看起来像这样 - (请记住,堆栈退绕已经被回溯例程取代.一旦回滚,回溯将把控制交给回卷器.完成)

0: MyExceptionBacktracer
1: initunwinder in System.pas
2: RaiseSignalException in System.Internal.ExcUtils.pas 

由于RaiseSignalException被调用SignalConverter,我被认为backtracelibc提供的函数与对堆栈的修改不兼容.因此,它无法读取超过该点的堆栈,但堆栈仍然存在于下方.

有谁知道该怎么做(或我的假设是否正确)？

更新3

我终于设法在OSX上获得了适当的堆栈跟踪.非常感谢Honza和Sebastian.通过结合他们的两种技术,我找到了有用的东西.

对于任何可以从中受益的人来说,这里是基本来源.请记住,我不太确定它是否100%正确,如果你能提出改进建议,请继续.在Delphi在错误线程上展开堆栈之前,此技术会挂起到异常,并补偿可能事先发生的任何堆栈帧损坏.

unit MyExceptionHandler;

interface

implementation

uses
  SysUtils;

var
  PrevRaiseException: function(Exc: Pointer): LongBool; cdecl;

function backtrace2(base : NativeUInt; buffer : PPointer; size : Integer) : Integer;
var SPMin   : NativeUInt;
begin
  SPMin:=base;
  Result:=0;
  while (size > 0) and (base >= SPMin) and (base <> 0) do begin

    buffer^:=PPointer(base + 4)^;
    base:=PNativeInt(base)^;

    //uncomment to test stacktrace
    //WriteLn(inttohex(NativeUInt(buffer^), 8));

    Inc(Result);
    Inc(buffer);
    Dec(size);

  end;
  if (size > 0) then buffer^:=nil;
end;

procedure UnInstallExceptionHandler; forward;

var
  InRaiseException: Boolean;

function RaiseException(Exc: Pointer): LongBool; cdecl;
var b : NativeUInt;
    c : Integer;
    buff : array[0..7] of Pointer;
begin
  InRaiseException := True;

  asm
    mov b, ebp
  end;

  c:=backtrace2(b - $4 {this is the compiler dependent value}, @buff, Length(buff));
  //... do whatever you want to do with the stacktrace

  Result := PrevRaiseException(Exc);
  InRaiseException := False;
end;

procedure InstallExceptionHandler;
var
  U: TUnwinder;
begin
  GetUnwinder(U);
  Assert(Assigned(U.RaiseException));
  PrevRaiseException := U.RaiseException;
  U.RaiseException := RaiseException;
  SetUnwinder(U);
end;

procedure UnInstallExceptionHandler;
var
  U: TUnwinder;
begin
  GetUnwinder(U);
  U.RaiseException := PrevRaiseException;
  SetUnwinder(U);
end;

initialization
  InstallExceptionHandler;
end.

Answer 1

您可以使用GetExceptionStackInfoProc,CleanUpStackInfoProc并GetStackInfoStringProc在Exception类,你需要保存堆栈跟踪GetExceptionStackInfoProc,然后用检索GetStackInfoStringProc将由RTL被调用,如果你使用StackTrace的财产Exception.也许您还可以查看https://bitbucket.org/shadow_cs/delphi-arm-backtrace,它在Android上演示了这一点.

要在Mac OS X上正确执行此操作,libc backtrace无法使用该函数,因为Delphi会在调用GetExceptionStackInfoProcfrom 时损坏堆栈帧Exception.RaisingException.必须使用自己的实现,该实现能够从不同的基址转移栈,可以手动校正.

GetExceptionStackInfoProc然后你会看起来像这样(我在这个例子中使用了XE5,根据你使用的编译器,这个例子只在Mac OS X上测试过,因此添加到EBP下的值可能会有所不同,Windows实现可能会有所不同或不同):

var b : NativeUInt;
    c : Integer;
    buff : array[0..7] of Pointer;
begin
  asm
    mov b, ebp
  end;
  c:=backtrace2(b - $14 {this is the compiler dependent value}, @buff, Length(buff));
  //... do whatever you want to do with the stacktrace
end;

并且backtrace2函数看起来像这样(请注意,实现中缺少停止条件和其他验证,以确保在堆栈遍历期间不会导致AV):

function backtrace2(base : NativeUInt; buffer : PPointer; size : Integer) : Integer;
var SPMin   : NativeUInt;
begin
  SPMin:=base;
  Result:=0;
  while (size > 0) and (base >= SPMin) and (base <> 0) do begin
    buffer^:=PPointer(base + 4)^;
    base:=PNativeInt(base)^;
    Inc(Result);

    Inc(buffer);
    Dec(size);
  end;
  if (size > 0) then buffer^:=nil;
end;