如何使用VBA向单元格添加数据验证

Question

我想使用VBA在单元格(可变)中添加"数据验证",并且数据验证列表中的范围也是可变的.直到现在我一直在使用它

这里"range1"是数据验证列表中的范围,"rng"是我想要数据验证的单元格

Dim range1, rng As range
Set range1 = range("a1:a5")
Set rng = range("b1")
With rng
With .Validation
    .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:= _
    xlBetween, Formula1:="range1"
End With
End With

我得到"应用程序定义和对象定义错误"

也有人可以解释我的不同论点的含义

With .Validation
.Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:= _
    xlBetween, Formula1:="range1"

Answer 1

使用这个:

Dim ws As Worksheet
Dim range1 As Range, rng As Range
'change Sheet1 to suit
Set ws = ThisWorkbook.Worksheets("Sheet1")

Set range1 = ws.Range("A1:A5")
Set rng = ws.Range("B1")

With rng.Validation
    .Delete 'delete previous validation
    .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, _
        Formula1:="='" & ws.Name & "'!" & range1.Address
End With

请注意,当你使用Dim range1, rng As range,只能rng有一个类型Range,但是range1是Variant.这就是我使用的原因Dim range1 As Range, rng As Range.
关于您可以阅读的参数的含义是MSDN,但简而言之:

• Type:=xlValidateList 表示验证类型,在这种情况下,您应该从列表中选择值
• AlertStyle:=xlValidAlertStop指定验证期间显示的消息框中使用的图标.如果用户从列表中输入任何值,他/她将收到错误消息.
• 在您的原始代码中,Operator:= xlBetween是奇怪的.只有在提供两个公式进行验证时才能使用它.
• Formula1:="='" & ws.Name & "'!" & range1.Address列表数据验证提供列表的地址与值(格式=Sheet!A1:A5)