如何将Perl正则表达式中的捕获存储到单独的变量中？

Question

我有一个正则表达式:

/abc(def)ghi(jkl)mno(pqr)/igs

如何将每个括号的结果捕获到3个不同的变量中,每个变量一个？现在我使用一个数组来捕获所有结果,它们按顺序出现,但后来我必须解析它们,列表可能很大.

@results = ($string =~ /abc(def)ghi(jkl)mno(pqr)/igs);

Answer 1

你的问题对我来说有点模棱两可,但我想你想做这样的事情:

my (@first, @second, @third);
while( my ($first, $second, $third) = $string =~ /abc(def)ghi(jkl)mno(pqr)/igs) {
    push @first, $first;
    push @second, $second;
    push @third, $third;
}

Answer 2

从5.10开始,您也可以使用命名捕获缓冲区:

#!/usr/bin/perl

use strict; use warnings;

my %data;

my $s = 'abcdefghijklmnopqr';

if ($s =~ /abc (?<first>def) ghi (?<second>jkl) mno (?<third>pqr)/x ) {
    push @{ $data{$_} }, $+{$_} for keys %+;
}

use Data::Dumper;
print Dumper \%data;

输出:

$VAR1 = {
          'first' => [
                       'def'
                     ],
          'second' => [
                        'jkl'
                      ],
          'third' => [
                       'pqr'
                     ]
        };

对于早期版本,您可以使用以下内容,以避免必须为每个捕获的缓冲区添加一行:

#!/usr/bin/perl

use strict; use warnings;

my $s = 'abcdefghijklmnopqr';

my @arrays = \ my(@first, @second, @third);

if (my @captured = $s =~ /abc (def) ghi (jkl) mno (pqr) /x ) {
    push @{ $arrays[$_] }, $captured[$_] for 0 .. $#arrays;
}

use Data::Dumper;
print Dumper @arrays;

输出:

$VAR1 = [
          'def'
        ];
$VAR2 = [
          'jkl'
        ];
$VAR3 = [
          'pqr'
        ];

但我喜欢将相关数据保存在单个数据结构中,因此最好回到使用哈希.这确实需要一个辅助数组,但是:

my %data;
my @keys = qw( first second third );

if (my @captured = $s =~ /abc (def) ghi (jkl) mno (pqr) /x ) {
    push @{ $data{$keys[$_]} }, $captured[$_] for 0 .. $#keys;
}

或者,如果变量的名字真的是first,second等,或者如果缓冲区的名字没有关系,而只是为了确实,你可以使用:

my @data;
if ( my @captured = $s =~ /abc (def) ghi (jkl) mno (pqr) /x ) {
    push @{ $data[$_] }, $captured[$_] for 0 .. $#captured;
}