对于每个字符串,执行一个函数/过程

Question

我想遍历一个字符串列表并执行一个函数/过程,每个字符串作为参数.

以下通用代码的最佳替代方法是什么(因为它不合法):

set serveroutput on;  
begin
    FOR r IN ('The', 'Quick', 'brown', 'fox')
    LOOP
        dbms_output.put_line( r );
   END LOOP;
end;

我假设可能有这种模式.

Answer 1

只是为了完整性,一个纯粹的PL/SQL解决方案.

SQL> set serveroutput on
SQL>
SQL> declare
  2      my_array sys.dbms_debug_vc2coll
  3          := sys.dbms_debug_vc2coll('The', 'Quick', 'brown', 'fox');
  4  begin
  5     for r in my_array.first..my_array.last
  6      loop
  7          dbms_output.put_line( my_array(r) );
  8     end loop;
  9  end;
 10  /
The
Quick
brown
fox

PL/SQL procedure successfully completed.

SQL>

这使用了preclared sys.dbms_debug_vc2coll数据类型,它具有相当大的定义......

SQL> desc sys.dbms_debug_vc2coll
 sys.dbms_debug_vc2coll TABLE OF VARCHAR2(1000)

SQL>

......所以,就像加里说的那样,你可能希望宣布自己的.特别是如果你的琴弦很短并且你有很多.

Answer 2

我一般使用我自己的集合类型，但是你可以使用内置的 sys.dbms_debug_vc2coll

select column_value from table(sys.dbms_debug_vc2coll('The', 'Quick', 'brown', 'fox'));

[我错误地使用了 column_name 而不是 column_value。谢谢指正】

Answer 3

这里的答案取决于字符串的来源。在非“数据库语言”中，您可能会以某种方式将字符串放入数组中，然后循环遍历该数组，如上面所示。问题是，该字符串列表是硬编码的，还是从数据库表中选择它们？

OMG Ponies 解决方案可以工作，但它涉及到可能不必要的选择。您可能更好地使用 PLSQL 表或变量 - 正如我所说，这取决于您如何将字符串放入您需要处理的程序中。这是使用 plsql 表的示例：

declare
  type myarray is table of varchar2(255) index by binary_integer;
  v_array myarray;
begin
  v_array(v_array.count + 1) := 'The';  
  v_array(v_array.count + 1) := 'quick';
  v_array(v_array.count + 1) := 'brown';
  v_array(v_array.count + 1) := 'fox';
  for i in 1..v_array.count loop
    dbms_output.put_line(v_array(i));
  end loop; 
end;
/

Answer 4

DECLARE
  -- 1. declare a list type
  TYPE STR_LIST_TYPE IS TABLE OF VARCHAR2(15);

  -- 2. declare the variable of the list
  V_STR_VALUES STR_LIST_TYPE;

  -- 3. optional variable to store single values
  V_STR_VALUE VARCHAR2(15);

BEGIN

  -- 4. initialize the list of values to be iterated in a for-loop
  V_STR_VALUES := STR_LIST_TYPE('String 1','String 2');

  -- 5. iterating over the values
  FOR INDX IN V_STR_VALUES.FIRST..V_STR_VALUES.LAST
  LOOP

    -- 6. accessing the value itself
    V_STR_VALUE := V_STR_VALUES(INDX);

  END LOOP;     
END;