Orgmode:一周内完成的任务报告

Question

是否可以要求组织模式报告我在一段时间内工作的TODO项目列表？

我们可以假设每个Todo条目都有一个时间标记,例如<2014-03-13 Thu 17:04>

Answer 1

一个快速的方法是查看议程中的日志.

您可以查看议程(请参阅组织模式文档中的议程视图).将议程移至您想要的时间段 - 日,周,月,年.将其置于日志模式(通过'l'键,在议程缓冲区的10.5命令一节中描述).这将显示该时间段您处理的任务和时间.

您还可以使用时钟表(请参阅第8.4.2节时钟表)获取详细报告,您可以在其中设置您感兴趣的所有详细信息.

(注意:我引用的章节标题编号是在Org-mode版本8.2.5h中 - 您的版本可能会有所不同,但这些部分仍然存在)

Answer 2

我使用这些议程视图来创建每日、每周和每月的评论。列出给定时间段内带有时间戳的所有内容，甚至是存档内容。它还在底部添加了一个时钟表，并在您导出议程视图（带有C-c a e）时导出到 html 文件。

;; define "R" as the prefix key for reviewing what happened in various
;; time periods
(add-to-list 'org-agenda-custom-commands
             '("R" . "Review" )
             )

;; Common settings for all reviews
(setq efs/org-agenda-review-settings
      '((org-agenda-files '("~/org/notes.org"
                            "~/org/projects.org"
                            ))
        (org-agenda-show-all-dates t)
        (org-agenda-start-with-log-mode t)
        (org-agenda-start-with-clockreport-mode t)
        (org-agenda-archives-mode t)
        ;; I don't care if an entry was archived
        (org-agenda-hide-tags-regexp
         (concat org-agenda-hide-tags-regexp
                 "\\|ARCHIVE"))
      ))
;; Show the agenda with the log turn on, the clock table show and
;; archived entries shown.  These commands are all the same exept for
;; the time period.
(add-to-list 'org-agenda-custom-commands
             `("Rw" "Week in review"
                agenda ""
                ;; agenda settings
                ,(append
                  efs/org-agenda-review-settings
                  '((org-agenda-span 'week)
                    (org-agenda-start-on-weekday 0)
                    (org-agenda-overriding-header "Week in Review"))
                  )
                ("~/org/review/week.html")
                ))


(add-to-list 'org-agenda-custom-commands
             `("Rd" "Day in review"
                agenda ""
                ;; agenda settings
                ,(append
                  efs/org-agenda-review-settings
                  '((org-agenda-span 'day)
                    (org-agenda-overriding-header "Day in Review"))
                  )
                ("~/org/review/day.html")
                ))

(add-to-list 'org-agenda-custom-commands
             `("Rm" "Month in review"
                agenda ""
                ;; agenda settings
                ,(append
                  efs/org-agenda-review-settings
                  '((org-agenda-span 'month)
                    (org-agenda-start-day "01")
                    (org-read-date-prefer-future nil)
                    (org-agenda-overriding-header "Month in Review"))
                  )
                ("~/org/review/month.html")
                ))