CMAKE_COMPILER_IS_GNUCXX和CMAKE_CXX_COMPILER_ID为空

Question

我目前正在玩CMake并希望检测编译器和编译器版本.我目前的情况CMakeLists.txt如下:

cmake_minimum_required (VERSION 2.6)

set (PROJECT "a_tour_of_c++")
set (GNUCXX_MINIMUM_VERSION "4.8")
set (CXX_STANDARD "c++11")

message ("${CMAKE_CXX_COMPILER}")       # C:/dev/MinGW/bin/g++.exe
message ("${CMAKE_CXX_COMPILER_ID}")    # EMPTY
message ("${CMAKE_COMPILER_IS_GNUCXX}") # EMPTY

if (CMAKE_COMPILER_IS_GNUCXX)
  if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS GNUCXX_MINIMUM_VERSION)
    message (FATAL_ERROR "GCC version must be at least ${GNUCXX_MINIMUM_VERSION}!")
  endif()
else()
  message (FATAL_ERROR "Invalid compiler!")
endif()

set (BUILD_DIR build)
set (HEADER_DIR include)
set (SOURCE_DIR src)
set (MAIN_FILE ${SOURCE_DIR}/main.cc)

set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=${CXX_STANDARD}")
project ($(PROJECT))
include_directories (${HEADER_DIR})
add_executable (${BUILD_DIR}/${PROJECT} ${MAIN_FILE})

该文件很好,我可以用这个文件成功地清理,构建和运行我的cli应用程序(如果我注释掉else编译器检查的-branch).

问题是,这两个CMAKE_CXX_COMPILER_ID和CMAKE_COMPILER_IS_GNUCXX是空的(CMAKE_CXX_COMPILER不).

我使用的是Microsoft Windows 8(6.3.9600)操作系统和MinGW,更详细的以下工具.

正如您在屏幕截图中所做的那样,我使用NetBeans IDE来简化整个构建过程.

所以我的问题是:

1. 可能的原因是,上述变量是空的？
2. 我的问题是否存在任何解决方法？

如果您发现我的(简单)CMakeLists.txt文件有任何其他问题,请告诉我.

Answer 1

将它放在 project命令后:

> cat CMakeLists.txt 
cmake_minimum_required(VERSION 2.8)

message("before:")
message(">    ${CMAKE_CXX_COMPILER}")
message(">    ${CMAKE_CXX_COMPILER_ID}")
message(">    ${CMAKE_COMPILER_IS_GNUCXX}")
message("-----------------")

project(Foo)

message("after:")
message(">    ${CMAKE_CXX_COMPILER}")
message(">    ${CMAKE_CXX_COMPILER_ID}")
message(">    ${CMAKE_COMPILER_IS_GNUCXX}")
message("-----------------")

> cmake -H. -B_builds
before:
>    
>    
>    
-----------------
-- The C compiler identification is GNU 4.8.1
-- The CXX compiler identification is GNU 4.8.1
-- Check for working C compiler: /usr/bin/cc
-- Check for working C compiler: /usr/bin/cc -- works
-- Detecting C compiler ABI info
-- Detecting C compiler ABI info - done
-- Check for working CXX compiler: /usr/bin/c++
-- Check for working CXX compiler: /usr/bin/c++ -- works
-- Detecting CXX compiler ABI info
-- Detecting CXX compiler ABI info - done
after:
>    /usr/bin/c++
>    GNU
>    1
-----------------
-- Configuring done
-- Generating done
-- Build files have been written to: /.../_builds

Answer 2

它可能会帮助您告诉 CMake 这是一个 C++ 项目。要做到这一点，你可以在project命令中这样说：

project ($(PROJECT) CXX)
#                   ^^^
# Note project type

您可能还想在检查变量之前执行此操作。