如何使用批处理脚本查找大型因子

Question

@echo off
if %1.==. ( echo Missing parameter! Try passing the number as a parameter     like   'factorial   10' without the quotes.
goto end )
setlocal enabledelayedexpansion
set /a count=0
set /a temp=0
set /a digits=1
set /a array1=1
for /L %%i IN (2,1,%1) do (
set /a temp=0
for /L %%j IN ( 1,1,!digits! ) do (
set /a temp=!temp!+!array%%j!*%%i
set /a array%%j=!temp!%%10
set /a temp=!temp!/10   ) 

set /a index=!digits!+1

for /L %%v IN (!index!,1,!index! ) do (
if !temp! NEQ 0 (
set /a array!index!=!temp!%%10
set /a temp/=10
set /a index+=1 ))
set /a digits=!index!-1)
for /l %%v IN ( !digits!,-1,1 ) do set array=!array!!array%%v!
echo !array!
echo Total # of decimal digits = !digits!
:end
pause

这是我到目前为止所得到的.10岁以下相当稳定!但是一旦我达到15或20,它就会错过几个数字.

我的编辑....

@echo off
if %1.==. ( echo Missing parameter! Try passing the number as a parameter  like   'factorial   10' without the quotes.
goto end )
setlocal enabledelayedexpansion
set /a count=0
set /a temp=0
set /a digits=1
set /a array1=1
for /L %%i IN (2,1,%1) do (
set /a temp=0
for /L %%j IN ( 1,1,!digits! ) do (
set /a temp=!temp!+!array%%j!*%%i
set /a array%%j=!temp!%%10
set /a temp=!temp!/10   ) 

for /l %%v IN ( 1,1,30 ) do (
if !temp! neq 0 (
set /a digits+=1
set /a array!digits!=!temp!%%10
set /a temp=!temp!/10
)))
for /l %%v IN ( !digits!,-1,1 ) do set array=!array!!array%%v!
echo !array!
echo Total # of decimal digits = !digits!
:end
pause

现在我强迫最后一个内循环运行30次,尽管temp在此之前已经为零.是否有任何方法可以编写类似于以下c代码的片段,而(temp){/ code goes here /}

只有当temp不为零时才执行此操作.

变量在批处理中的大小是否存在任何限制？我知道这是一个痛苦*调试批处理计算程序,我只是想在我知道所有的编程语言编写这一点,就这样我就可以比较它们的速度.有人可以指出我在这里做错了什么.

编辑........ 22/12/13

@echo off
if %1.==. ( echo Missing parameter! Try passing the number as a parameter like   'factorial   10' without the quotes.
goto end )
setlocal enabledelayedexpansion

set /a count=0
set /a tempo=0
set /a digits=1
set /a array1=1

for /f "tokens=1-4 delims=:.," %%a IN ("%time%") do (     
set /a "start=(((%%a*60)+1%%b %% 100)*60+1%%c %%100)*100+1%%d %% 100"
)

for /L %%i IN (2,1,%1) do (
set /a tempo=0
for /L %%j IN ( 1,1,!digits! ) do (
set /a tempo=!tempo!+!array%%j!*%%i
set /a array%%j=!tempo!%%10000
set /a tempo=!tempo!/10000   ) 

for /l %%v IN (1,1,2) do (
if !tempo! neq 0 (
set /a digits+=1
    set /a array!digits!=tempo%%10000
set /a tempo=tempo/10000
))
)

for /l %%v IN ( !digits!,-1,1 ) do set array=!array!!array%%v!
echo !array!  
echo Total # of decimal digits = !digits!

for /f "tokens=1-4 delims=:.," %%a in ("%time%") do (
set /a "end=(((%%a*60)+1%%b %% 100)*60+1%%c %%100)*100+1%%d %% 100"
)

set /a elapsedcs=end-start
set /a elapseds=elapsedcs/100
set /a elapsedcs=elapsedcs%%100
echo %elapseds%.%elapsedcs% seconds
:end
rem label should never be the last statement

这是你的意思aacini？

Answer 1

为了实现批量大数字的快速算术运算，您必须将 Bignum 拆分为可通过命令的 32 位运算进行管理的数字组set /A。最大 32 位有符号整数为 2147483647，因此可以通过这种方式相乘的最大数字组为 4，因为 5 位数字 (99999 x 99999) 超出了最大数字。加法和乘法必须从右到左实现，将“进位”转换为左侧的下一组。减法和除法必须从左到右进行，将“借位”翻译为右侧的下一组。下面的批处理文件使用此方法将 Bignum 连续乘以 4 位因数，因此最多可以计算 9999！只要包含 4 位数字组的所有变量都符合环境的64 MB 大小限制（在“设置环境变量”下查找“65,536KB 最大大小”）。结果直接输出到屏幕，以避免一个 Batch 变量的 8192 位限制。

编辑：我稍微修改了程序以便运行得更快并获得结果中的位数。

@echo off

if "%1" equ "" (
   echo Missing parameter! Try passing the number as a parameter like 'factorial 10' without the quotes.
   goto end
)

setlocal EnableDelayedExpansion

rem Calculate the factorial
set /A g1=1, groups=1
for /L %%n in (2,1,%1) do (
   set carry=0
   for /L %%g in (1,1,!groups!) do (
      set /A group=g%%g*%%n+carry, g%%g=group%%10000, carry=group/10000
   )
   if !carry! neq 0 (
      set /A groups+=1
      set g!groups!=!carry!
   )
)

rem Show the factorial
set /P "=!g%groups%!" < NUL
set /A groupsM1=groups-1
for /L %%g in (%groupsM1%,-1,1) do (
   set group=000!g%%g!
   set /P "=!group:~-4!" < NUL
)
echo/

rem Get the number of digits
set digits=0
for /L %%i in (0,1,3) do if "!g%groups%:~%%i,1!" neq "" set /A digits+=1
set /A digits+=4*groupsM1
echo Total # of decimal digits = %digits%

:end
pause