使用cmd或批处理解析2个文本文件

Question

我正在尝试解析2个文本文件并使用cmd或批处理从两个文件中创建一个文件,是否可以不使用任何其他程序或vbscript？这是一个例子:number.txt包含

ren 01.mp3
ren 02.mp3
ren 03.mp3

等等...

names.txt 包含

Chapter_00_Introduction.mp3
Chapter_01_This_is_Chapter_01.mp3
Chapter_02_This_is_Chapter_02.mp3
Chapter_03_This_is_Chapter_03.mp3

等等...

我想要的是用这个内容生成第三个文件(output.txt)

ren 01.mp3 Chapter_00_Introduction.mp3
ren 02.mp3 Chapter_01_This_is_Chapter_01.mp3
ren 03.mp3 Chapter_02_This_is_Chapter_02.mp3

是的,名称不匹配(01.mp3实际上是引言,02.mp3是第1章,依此类推).

这是我到目前为止:

@echo off
setLocal EnableDelayedExpansion
for /f "tokens=*" %%a in (Number.txt) do (
   For /f "tokens=*" %%b in (Names.txt) Do (Echo %%a%%b.mp3>>output.txt)
)
Exit

结果是

Ren 01.mp3 Chapter_00_Introduction.mp3
Ren 01.mp3 Chapter_01_This_is_chapter_02.mp3
Ren 01.mp3 Chapter_03__This_is_chapter_03.mp3
Ren 01.mp3 Chapter_04__This_is_chapter_04.mp3

Answer 1

@echo off
setLocal EnableDelayedExpansion
< Names.txt (
   for /f "tokens=*" %%a in (Number.txt) do (
      set /P name=
      Echo %%a !name!
   )
) >output.txt
Exit