如何在sparql中连接值列表？

Question

假设我有一个uri http://dbpedia.org/page/Manmohan_Singh, 现在他的标签为dbpprop:years.

当我写一个像这样的查询

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
            PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
            PREFIX dbpedia: <http://dbpedia.org/resource/>PREFIX dcterms: <http://purl.org/dc/terms/>
            PREFIX dbpedia-owl: <http://dbpedia.org/ontology/>PREFIX category: <http://dbpedia.org/resource/Category:>
            PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>PREFIX foaf: <http://xmlns.com/foaf/0.1/>PREFIX dbpprop: <http://dbpedia.org/property/>
            PREFIX dbprop: <http://dbpedia.org/property/>PREFIX grs: <http://www.georss.org/georss/>
            PREFIX category: <http://dbpedia.org/resource/Category:>
            PREFIX owl: <http://www.w3.org/2002/07/owl#>
            PREFIX dbpprop: <http://dbpedia.org/property/>
            PREFIX foaf: <http://xmlns.com/foaf/0.1/>
            SELECT DISTINCT ?x ?name ?abs ?birthDate ?birthplace ?year ?party ?office ?wiki WHERE {
            ?x owl:sameAs? dbpedia:Manmohan_Singh.
            ?x dbpprop:name ?name.
            ?x dbpedia-owl:birthDate ?birthDate.
            ?x dbpedia-owl:birthPlace ?birthplace.
            ?x dbpprop:years ?year.
            ?x dbpprop:party ?party.
            ?x dbpedia-owl:office ?office.
            ?x foaf:isPrimaryTopicOf ?wiki.
            ?x rdfs:comment ?abs.
            FILTER(lang(?abs) = 'en')


            }

我得到每年的结果在不同的行..因此重复其他列的数据.有没有一种方法可以将它作为一个列表中的列表,就像所有年份中的一个逗号分隔或像这样的smthng？

类似于prop dbpedia-owl:office

Answer 1

这与聚合SPARQL查询的结果类似,但问题实际上有点复杂,因为有多个变量具有多个结果. ?name,?office并且?birthPlace有同样的问题.

你可以使用它来解决这个问题group_concat,但你也需要使用distinct它,以避免?year在你的连接字符串中多次重复相同的操作. group by减少解决方案中的行数,但在每个行中,您都有一组未分组的变量值.例如,既然?year不在group by,你有一组值?year,你必须对它们做一些事情.例如,您可以select (sample(?year) as ?aYear)从集合中只抓取一个,或者您可以像我们在这里完成的那样,并将select (group_concat(distinct ?year;separator=", ") as ?years)不同的值连接成一个字符串.

你需要一个像下面这样的查询,它产生一行:

SELECT ?x
       (group_concat(distinct ?name;separator="; ") as ?names)
       ?abs
       ?birthDate
       (group_concat(distinct ?birthplace;separator=", ") as ?birthPlaces)
       (group_concat(distinct ?year;separator=", ") as ?years)
       ?party
       (group_concat(distinct ?office;separator=", ") as ?offices)
       ?wiki
WHERE {
  ?x owl:sameAs? dbpedia:Manmohan_Singh.
  ?x dbpprop:name ?name.
  ?x dbpedia-owl:birthDate ?birthDate.
  ?x dbpedia-owl:birthPlace ?birthplace.
  ?x dbpprop:years ?year.
  ?x dbpprop:party ?party.
  ?x dbpedia-owl:office ?office.
  ?x foaf:isPrimaryTopicOf ?wiki.
  ?x rdfs:comment ?abs.
  FILTER(langMatches(lang(?abs),"en"))
}
group by ?x ?abs ?birthDate ?party ?wiki

SPARQL结果

Answer 2

查看一下，GROUP_CONCAT但检索多行中的数据（您可以排序以将重复项彼此相邻）并在代码中处理可能更容易。