习惯于在haskell中汇总Maybe Int列表的方法

Question

有没有更惯用的方式来实现以下内容？我觉得我错过了摆脱lambda的方法,但无法找到将其转换为无点的方法.也许还有另一种非适用的方式更直接？

import Data.Maybe
import Control.Applicative

foldl (\x y -> pure (+) <*> x <*> y) (Just 0) [Just 3, Just 4]
-- Just 7

foldl (\x y -> pure (+) <*> x <*> y) (Just 0) [Just 3, Just 4, Nothing]
-- Nothing

Answer 1

我只是使用sequenceControl.Monad:

> fmap sum $ sequence [Just 3, Just 4]
Just 7
> fmap sum $ sequence [Just 3, Just 4, Nothing]
Nothing

对于无点形式:

sumMaybe :: Num a => [Maybe a] -> Maybe a
sumMaybe = fmap sum . sequence

Answer 2

消除lambda的最直接方法是使用liftA2; 这正是你写的代码

liftA2 :: (a -> b -> c) -> f a -> f b -> f c
liftA2 f x y = pure f <*> x <*> y

foldl (liftA2 (+)) (Just 0) [Just 1, Just 2]

那么我们有一些选择如何传播错误.这段代码认为任何一个Nothing都会导致完全失败.我们可以通过@bhekilr建议使用的两个步骤来做到这一点sequence.

sum <$> sequence [Just 1, Just 2]     sum <$> sequence [Just 1, Nothing]
Just (sum  [1,2])                     sum <$> Nothing
Just 3                                Nothing

我们还可以使用这样的事实,即(+)引入一个Monoid值,以便"忽略" Nothings.最字面意思是

import Data.Monoid

getSum $ foldMap (maybe mempty Sum) [Just 1, Just 2, Nothing]
-- equivalent to, but faster than
getSum . mconcat . map (maybe mempty Sum) $ [Just 1, Just 2, Nothing]
getSum . mconcat $ [Sum 1, Sum 2, Sum 0]
3

但是,我们也可以使用catMaybe从Data.Monoid做两步

sum . catMaybes $ [Just 1, Just 2, Nothing]
sum [1, 2]
3

Answer 3

我觉得foldM这里效果很好.

import Control.Monad
sumMay = foldM (fmap . (+)) 0

我认为它是最清晰的,因为它映射(Ba duh duh ching)到你在纯代码中所做的事情.