使用VBA宏在工作簿中的Excel表上执行SQL查询

Question

我正在尝试制作一个excel宏,它将在Excel中提供以下功能:

=SQL("SELECT heading_1 FROM Table1 WHERE heading_2='foo'")

允许我使用SQL查询在我的工作簿表中搜索(甚至可能插入)数据.

这是我到目前为止所做的:

Sub SQL()

Dim cn As ADODB.Connection
Dim rs As ADODB.Recordset

strFile = ThisWorkbook.FullName
strCon = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & strFile _
& ";Extended Properties=""Excel 12.0;HDR=Yes;IMEX=1"";"

Set cn = CreateObject("ADODB.Connection")
Set rs = CreateObject("ADODB.Recordset")

cn.Open strCon

strSQL = "SELECT * FROM [Sheet1$A1:G3]"

rs.Open strSQL, cn

Debug.Print rs.GetString

End Sub

我的脚本就像一个带有硬编码范围的魅力,例如上面代码段中的那个.它也适用于静态命名范围.

但是,它不适用于动态命名范围或TABLE NAMES,这对我来说是最重要的.

我找到答案的最接近的是这个遭受同样痛苦的人:http://www.ozgrid.com/forum/showthread.php？t = 72973

帮助任何人？

编辑

到目前为止我已经煮熟了,然后我可以在我的SQL查询中使用结果名称.限制是我需要知道表格在哪张纸上.我们可以做些什么吗？

Function getAddress()

    myAddress = Replace(Sheets("Sheet1").Range("Table1").address, "$", "")
    myAddress = "[Sheet1$" & myAddress & "]"

    getAddress = myAddress

End Function

谢谢!

Answer 1

您可以做的一件事是获取动态命名范围的地址,并将其用作SQL字符串中的输入.就像是:

Sheets("shtName").range("namedRangeName").Address

哪个会吐出一个地址字符串,比如说 $A$1:$A$8

编辑:

正如我在下面的评论中所说,您可以动态获取完整地址(包括工作表名称),并直接使用它或解析工作表名称以供以后使用:

ActiveWorkbook.Names.Item("namedRangeName").RefersToLocal

这导致字符串如=Sheet1!$C$1:$C$4.因此,对于上面的代码示例,您的SQL语句可能是

strRangeAddress = Mid(ActiveWorkbook.Names.Item("namedRangeName").RefersToLocal,2)

strSQL = "SELECT * FROM [strRangeAddress]"

Answer 2

Public Function GetRange(ByVal sListName As String) As String

Dim oListObject As ListObject
Dim wb As Workbook
Dim ws As Worksheet

Set wb = ThisWorkbook

For Each ws In wb.Sheets
    For Each oListObject In ws.ListObjects
        If oListObject.Name = sListName Then
            GetRange = "[" & ws.Name & "$" & Replace(oListObject.Range.Address, "$", "") & "]"
        Exit Function
        End If
    Next oListObject
Next ws


End Function

在你的SQL中使用它就像这样

sSQL = "Select * from " & GetRange("NameOfTable") & ""

Answer 3

基于 Joan-Diego Rodriguez 的例程和 Jordi 的方法和一些 Jacek Kotowski 的代码 - 此函数将活动工作簿的任何表名转换为 SQL 查询的可用地址。

MikeL 的注释：添加“[#All]”包括避免您报告的问题的标题。

Function getAddress(byVal sTableName as String) as String 

    With Range(sTableName & "[#All]")
        getAddress= "[" & .Parent.Name & "$" & .Address(False, False) & "]"
    End With

End Function