RSpec - 从“应该”语法升级到“期望”语法的脚本？

Question

我有数百个文件，其中也有数百个“应该”语句。

是否有任何自动方法可以将这些文件更新为新语法？

我想要既可以创建新文件又可以内联修改现有文件的选项。

Answer 1

sed 是一个很好的工具。

下面将处理当前目录中的所有文件并将它们写入目录中的新文件_spec_seded。目前，这可以处理大约 99% 以上的更改，但您可能仍然需要进行一些手动更改（数量取决于您的代码和编码风格）。

与往常一样，使用 sed 脚本时，您应该检查结果、运行差异并手动查看文件。理想情况下，您使用 git，这有助于使差异变得更加容易。

filenum=1
find . -type f -name '*_spec.rb' | while read file; do
  mkdir -p ../_spec_seded/"${file%/*}"
  echo "next file...$filenum...$file"
  let filenum+=1
  cp "$file" ../_spec_seded/"$file"

  sed -i '                           # Exclude:
/^ *describe .*do/! {                # -describe...do descriptions
  /^ *it .*do/! {                    # -it...do descriptions
    /^[[:blank:]]*\#/! {             # -comments
      /^ *def .*\.should.*/! {       # -inline methods
        /\.should/ {
          s/\.should/)\.to/                      # Change .should to .to
          s/\(\S\)/expect(\1/                    # Add expect( at start of line.
          /\.to\( \|_not \)>\=/ s/>\=/be >\=/    # Change operators for
          /\.to\( \|_not \)>[^=]/ s/>/be >/      # >, >=, <, <= and !=
          /\.to\( \|_not \)<\=/ s/<\=/be <\=/
          /\.to\( \|_not \)<[^=]/ s/</be </
          /\.to\( \|_not \)\!\=/ s/\!\=/be \!\=/
        }

        /\.to +==\( +\|$\)/ s/==/eq/
        /=\~/ {                                      # Change match operator
          s/=\~/match(/
          s/$/ )/
          s/\[ )$/\[/
        }

        s/[^}.to|end.to]\.to /).to /                 # Add paren
        /eq ({.*} )/ s/ ({/ ( {/                     # Add space
        /to\(_\|_not_\)receive/ s/_receive/ receive/ # receive
        /\.to eq \[.*\]/ {
          s/ eq \[/ match_array([/
          s/\]$/\])/
        }

        /expect.*(.*lambda.*{.*})/ {                 # Remove unneeded lambdas
          s/( *lambda *{/{/
          s/ })\.to / }\.to /
        }

        /expect *{ *.*(.*) *})\.to/ {                  # Fix extra end paren
          s/})\.to/}\.to/
        }
      }
    }
  }
}' ../_spec_seded/"$file"
done

请谨慎使用。目前，为了安全起见，脚本_seded/首先创建新文件以供审查。该脚本放置在/spec目录中并从那里运行。如果您有数百个文件，这可以节省您数小时或数天的工作时间！如果您使用此功能，我建议“第 2 步”手动将文件复制到_spec_seded自身spec并运行它们。我建议您不要只重命名整个目录。一方面，诸如此类的文件spec_helper.rb当前未复制到_spec_seded.

11/18/2013 注意：我继续升级这个脚本。覆盖更多的边缘情况，并使匹配更加具体，并排除更多的边缘情况，例如注释行。

PS 可以通过以下方式查看应审查的差异（从项目根目录）：

diff -r /spec /_spec_seded

git 也有很好的 diff 选项，但我喜欢在将文件添加到 git 之前先查看一下。

Answer 2

迟来的更新，主要是针对那些可能通过搜索引擎找到此页面的人。

\n\n

为此，请使用 Yuji Nakayama 出色的Transpec gem。我已经在不同的项目中使用了 10 多次，没有出现任何问题。

\n\n

来自网站：

\n\n

\n

Transpec 可让您立即将 RSpec 2 规格升级到 RSpec 3。它支持几乎所有 RSpec 3 更改的转换，并且是 RSpec 团队推荐的\xe2\x80\x99s。

\n\n

此外，即使您\xe2\x80\x99 目前不打算将其升级到 RSpec 3，您也可以在 RSpec 2 项目中使用它。

\n

\n