Clojure中的不一致:宏中的函数和IllegalArgumentException

Question

以下两个在宏中使用函数的示例会导致无错误的评估.

(defmacro works []
  (let [f (fn [] 1)]
    `(~f)))
(works)
;; => 1

(defn my-nullary-fn []
  (fn [] 2))
(defmacro also-works []
  (let [f (my-nullary-fn)]
    `(~f)))
(also-works)
;; => 2

然而,

(defmacro does-not-work []
  (let [f (constantly 3)]
    `(~f)))
(does-not-work)

投

java.lang.IllegalArgumentException: No matching ctor found
for class clojure.core$constantly$fn__4051 

同样,

(defn my-unary-fn [x]
  (fn [] x))
(defmacro also-does-not-work []
  (let [f (my-unary-fn 4)]
    `(~f)))
(also-does-not-work)

投

java.lang.IllegalArgumentException No matching ctor found
for class user$my_other_fn$fn__12802

可能是什么原因？有没有函数对象之间的差异返回的fn,my-nullary-fn,constantly和my-unary-fn？

我正在运行Clojure 1.5.1.

CLJ-946可能相关.

Answer 1

看看clojure.lang.Compiler.ObjExpr#emitValue().直接出现在代码中的任何实例对象(或者在宏扩展结果的情况下生成的代码)都必须:

• 属于类型的编译器知道如何实例化或发出引用; 要么
• 已经print-dup为它们的类型定义了,在这种情况下,编译器通过阅读器的往返来发出对象实例化.

函数对象确实有一个print-dup实现,但它构造了read-eval表单,它只调用函数类构造函数的0参数版本:

(print-dup (fn [] 1) *out*)
;; #=(user$eval24491$fn__24492. )
(let [x 1] (print-dup (fn [] x) *out*))
;; #=(user$eval24497$fn__24498. )

Clojure闭包是通过函数类实现的,函数类接受它们的闭合变量值作为构造函数参数.因此:

(let [f (fn [] 1)] (eval `(~f)))
;; 1
(let [x 1, f (fn [] x)] (eval `(~f)))
;; IllegalArgumentException No matching ctor found ...

所以现在你知道了,并且知道为什么要避免直接将函数对象插入到生成的代码中,即使它"有效".