如何将关联数组分配给zsh中的另一个变量？

Question

在zsh中,有没有办法将关联数组分配给另一个变量？我想这样的事情:

typeset -A orig
orig=(key1 val1 key2 val2)
typeset -A other
other=$orig
print '$orig:  '$orig
print '$other: '$other
print '$orig[key1]: '$orig[key1]
print '$other[key1]: '$other[key1]

这将打印:

$orig:  val1 val2
$other: val1 val2
$orig[key1]: val1
$other[key1]: 

我希望能够使用$other[key1]并获得val1.

我知道我可以迭代按键并逐项复制,但我真的想避免这种情况.还有,eval是邪恶的:)

我已尝试过other=($orig)和其他变体,但这将获取我的值orig并创建为这样的关联数组

other=(val1 val2)

所以不other[key1]返回任何东西并other[val1]返回val2,这不是我想要的.

如果我理解正确的,什么是我的每一次尝试事情是$other越来越的数组值的$orig,不需钥匙.如何让它接收键和值并在它们之间保持正确的关联？

我不担心空值,如果这甚至会成为一个问题,因为我肯定$orig会表现得很好.

谢谢!

Answer 1

你必须深入研究参数扩展标志的精彩世界:) k和v标志可以一起使用来强制关联数组扩展到它的键和值.

$ typeset -A orig
$ orig=(key1 val1 key2 val2)
$ print ${(kv)orig}
key1 val1 key2 val2

然后,您可以使用该set命令使用该扩展生成的交替键/值填充副本.

$ typeset -A other
$ set -A other ${(kv)orig}
$ print $other[key1]
val1

这些和其他标志记录在man zshexpn"参数扩展标志"下,这是我最喜欢的zsh功能之一.

Answer 2

zsh: bad set of key/value pairs for associative array

无法逃避的完美世界：

$ typeset -A old new
$ old=(k1 v1 k2 v2 k3 v3)
$ typeset old    # old=( k1 v1 k2 v2 k3 v3 )

...不存在并且您的数组通常包含空值：

$ old[k2]=
$ typeset old    # old=( k1 v1 k2 '' k3 v3 )

...因此你需要使用"（引用）、@（转义）和f（字段分隔）：

$ typeset new    # new=( )
$ new=("${(@fkv)old}")
$ typeset new    # new=( k1 v1 k2 '' k3 v3 )

man zshexpn有关参数扩展标志的更多信息，请参见 参考资料。