使用Qt编译项目后,将文件复制到构建目录

Question

我已经看到了几个建议,但没有任何真正对我有用的东西.我只需要将文件复制到所需的目标目录.

比如说,从这个回答:

install_it.path = %{buildDir}
install_it.files += %{sourceDir}/settings.ini

INSTALLS += install_it

变量%{buildDir}和%{sourceDir}应界定,以使这项工作.好吧,没问题%{sourceDir}:它只是..但我怎么能得到%{buildDir}？

EDIT1

说,我my_project这里有一个项目:

/path/to/my_project

因此,释放的构建路径是这样的:/path/to/my_project-build-Desktop-release,

调试构建路径是这样的: /path/to/my_project-build-Desktop-debug

我有文件要复制到目标目录: /path/to/my_project/copy_to_install_dir

因此,我希望在发布版本时/path/to/my_project/copy_to_install_dir将所有文件复制到/path/to/my_project-build-Desktop-release.而且,调试构建的方式相同.

我找不到包含完整目标路径的变量,即/path/to/my_project-build-Desktop-release用于调试构建.

以防万一:我使用Windows,但无论如何我正在寻找跨平台解决方案.

EDIT2

准确的解决方案,面向未来的读者:

install_it.path = $$OUT_PWD
install_it.files = copy_to_install_dir/*

INSTALLS += \
    install_it

Answer 1

选择的答案是正确的但它需要打电话make install,在我看来这是令人讨厌或容易出错的.相反,要将文件复制到构建目录,请使用:

copydata.commands = $(COPY_DIR) $$PWD/required_files $$OUT_PWD
first.depends = $(first) copydata
export(first.depends)
export(copydata.commands)
QMAKE_EXTRA_TARGETS += first copydata

哪里required_files必须用正确的路径替换.$$PWD是当前.pro文件的路径,您可能不需要这个.

注:我发现这个解决方案在这里.我建议阅读整篇文章,因为它解释了它的工作原理.

Answer 2

我有幸浪费了几个小时,我想我会在这件事上分享我的发现.这Paglian的方法的修饰变体在这里.由于我使用的是Windows(没有mingw),因此该方法不起作用.所以这是修改后的变体:

# using shell_path() to correct path depending on platform
# escaping quotes and backslashes for file paths
copydata.commands = $(COPY_FILE) \"$$shell_path($$PWD\\archive.png)\" \"$$shell_path($$OUT_PWD)\"
first.depends = $(first) copydata
export(first.depends)
export(copydata.commands)
QMAKE_EXTRA_TARGETS += first copydata

由于这使它成为跨平台,你当然也可以在Linux,MacOS或你拥有的东西中使用这种方法.请注意我正在复制一个文件,所以不是$(COPY_DIR)我正在使用$(COPY_FILE).根据需要进行调整.

如果你想将文件复制到二进制文件最终的确切路径(因为二进制文件将在$$ OUT_PWD的子文件夹中结束(调试或发布,至少在使用带有MSVC 14/cdb的Qt Creator构建时) .exe/Code :: Blocks Makefiles配置)你需要这个:

# adapted from https://stackoverflow.com/a/2581068
CONFIG(debug, debug|release) {
    VARIANT = debug
} else {
    VARIANT = release
}

请注意,即使二进制文件最终存在于子文件夹中,QtCreator也会执行二进制文件$$OUT_PWD,因此它需要查找文件资源$$OUT_PWD,而不是调试子文件.这意味着你QIcon("archive.png")除了可执行文件之外不能做并期望它找到它.

这当然可以通过以下方式轻松解决:

QDir exeDir(QCoreApplication::applicationDirPath());
QIcon qIcon(exeDir.filePath("archive.png"));

如果你决定这是你想要的,你显然需要编辑$$(COPY_FILE)(in .pro)的最后一个参数,如下所示:\"$$shell_path($$OUT_PWD)\\$$VARIANT\"

还有一点需要注意的是(在我的情况下无论如何)Qt Creator(4.0.1)并不总是构建.pro文件,因为它没有检测到配置中的任何更改,因此要在Makefile中反映上述更改(因此在构建项目时运行)您必须通过Build->run qmake从应用程序菜单运行来实际构建.pro .为确保一切顺利,请按Alt + 4(在Windows上)查看编译输出.

Answer 3

这就是我们在QtSerialPort中使用的内容:

target_headers.files  = $$PUBLIC_HEADERS
target_headers.path   = $$[QT_INSTALL_HEADERS]/QtSerialPort
INSTALLS              += target_headers

mkspecs_features.files    = $$QTSERIALPORT_PROJECT_ROOT/src/serialport/qt4support/serialport.prf
mkspecs_features.path     = $$[QT_INSTALL_DATA]/mkspecs/features
INSTALLS                  += mkspecs_features

基本上,您设置目标的文件和路径,然后将其附加到INSTALLS变量中.您仍然需要的是$$OUT_PWD我们也广泛使用的变量QtSerialPort.这将为您提供构建目录的根目录.

它是那些未记录的qmake功能之一,但它非常有用.

另外,对于一般的源目录,你不应该假设"." 等等,因为当您运行包含"."的包装器应用程序时可能会有所不同.将指向那而不是你期望的:qmake源项目根.在这些情况下,使用PWD指向源的变量更安全,而不是OUT_PWD指向构建文件夹.

只是给出一个关于这两个变量与真实场景的差异的粗略示例,在这里您可以找到我们在QtSerialPort中所做的事情:

system("echo QTSERIALPORT_PROJECT_ROOT = $$PWD >> $$OUT_PWD/.qmake.cache")
system("echo QTSERIALPORT_BUILD_ROOT = $$OUT_PWD >> $$OUT_PWD/.qmake.cache")

前者是源项目的根,后者是构建目录.它们可能是相同的,但在许多情况下它们不是,例如,当通过QtCreator构建时只为其中一个.