在'emacs --deamon'之后,我无法在emacsclient框架中看到新的主题.它的工作原理是'emacs Mx server-start'

Question

最小配置https://www.refheap.com/18816

场景1.

• 从终端运行'emacs'.
• Mx服务器启动
• 从终端运行'emacsclient -c'.
• 效果:主题应用.

情景2.

• 从终端运行'emacs --daemon'
• 运行'emacsclient -c'
• 效果:主题未应用.

这是为什么？

.emacs.d/init.d config:

(require 'package)
(package-initialize)

(defun install-pack (p)
"A utility function to help in installing emacs package."
(unless (package-installed-p p) (package-install p)))

(defun install-packs (packs)
"A utility function to help in installing emacs packages."
(unless package-archive-contents
        (package-refresh-contents))
(dolist (p packs) (install-pack p)))

;(load-theme 'tronesque)
(load-theme 'tronesque t)

要么

;(load-theme 'tronesque)
;;(load-theme 'tronesque t)
(custom-set-variables
;; custom-set-variables was added by Custom.
'(custom-enabled-themes (quote (tronesque)))
'(custom-safe-themes (quote    ("b8f561a188a77e450ab8a060128244c81dea206f15c1152a6899423dd607b327" default))))
 (custom-set-faces
 ;; custom-set-faces was added by Custom.
 )

Answer 1

对于Emacs 24,

(if (daemonp)
    (add-hook 'after-make-frame-functions
        (lambda (frame)
            (select-frame frame)
            (load-theme 'tronesque t)))
    (load-theme 'tronesque t))

要么

(if (daemonp)
    (add-hook 'after-make-frame-functions
        (lambda (frame)
            (with-selected-frame frame
                (load-theme 'tronesque t))))
    (load-theme 'tronesque t))

应该做.

Answer 2

使用所有提到的方法,从第二帧创建开始,主题被重新加载是徒劳的.

为了加载它我只做了一次:

(if (daemonp)
    (add-hook 'after-make-frame-functions (lambda (frame)
                        (when (eq (length (frame-list)) 2)
                            (progn
                              (select-frame frame)
                              (load-theme 'tronesque)))))
  (load-theme 'tronesque 1))

更新

在使用杰出主题的Emacs 24.5.1中进行一些测试并使用emacs作为守护进程之后,我遇到了一些问题.

如果我的第一个客户端是终端emacsclient -t,后来我打开一个窗口客户端emacsclient -c,则窗口客户端会丢失主题配置.

然后我提出了这个解决方案:

;; theme
(defvar my:theme 'distinguished)
(defvar my:theme-window-loaded nil)
(defvar my:theme-terminal-loaded nil)

(if (daemonp)
    (add-hook 'after-make-frame-functions(lambda (frame)
                       (select-frame frame)
                       (if (window-system frame)
                           (unless my:theme-window-loaded
                             (if my:theme-terminal-loaded
                                 (enable-theme my:theme)
                               (load-theme my:theme t))
                             (setq my:theme-window-loaded t))
                         (unless my:theme-terminal-loaded
                           (if my:theme-window-loaded
                               (enable-theme my:theme)
                             (load-theme my:theme t))
                           (setq my:theme-terminal-loaded t)))))

  (progn
    (load-theme my:theme t)
    (if (display-graphic-p)
        (setq my:theme-window-loaded t)
      (setq my:theme-terminal-loaded t))))

我知道,这不是那么优雅,但解决了两个问题(不必要的重新加载和丢失配置).

Answer 3

load-theme由于它是守护进程启动，因此在涉及该函数时没有创建任何框架。启动后，您通过输入“emacsclient -c”创建了一个新框架，当然什么也没有发生。

所以你必须告诉 emacs 在创建框架后应用主题。钩子after-make-frame-functions是为此而设计的：

(if (daemonp)
    (add-hook 'after-make-frame-functions
              (lambda (frame)
                (load-theme 'tronesque t)))
    (load-theme 'tronesque t))

如果是守护进程启动，则在创建框架后加载主题，否则直接加载主题。