Delphi中的记录和通用容器

Question

我对Generic Containers(TList)的记录略微发疯(唱着Queen的歌).首先,看看这段代码:

  TItemRec = record
  private
    FSender    : TAction;
    FOwnerPack : HModule;
    FDockPanel : TdxDockPanel;
    procedure SetDockPanel(const Value: TdxDockPanel);
    procedure SetOwnerPack(const Value: HModule);
    procedure SetSender(const Value: TAction);
  public
    property Sender: TAction read FSender write SetSender;
    property OwnerPack: HModule read FOwnerPack write SetOwnerPack;
    property DockPanel: TdxDockPanel read FDockPanel write SetDockPanel;
  end;

  TPackRec = record
  private
    FHandle  : HModule;
    var FCounter : Int16;
    procedure SetCounter(const Value: Int16);
    procedure SetHandle(const Value: HModule);
  public
    property Handle: HModule read FHandle write SetHandle;
    property Counter: Int16 read FCounter write SetCounter;
    procedure ChangeCounter(IncValue: Boolean = True);
  end;

  TRecList = class(TList<TItemRec>)
  public
    procedure CloseDockPanels;
  end;

  TPackList = class(TList<TPackRec>)
  strict private
    procedure DoChanges(const APack: HModule; const AAdd: Boolean = True);
  public
    procedure CheckForUnusedItems;
    procedure AppendRef(const APack: HModule);
    procedure DeleteRef(const APack: HModule);
    procedure ClosePackages;
  end;

  TfrmMain = class(TForm)
  private
    FRecList  : TRecList;
    FPackList : TPackList;
  public
  end;

........................

procedure TPackList.CheckForUnusedItems;
var
  i : Int16;
  Flag : Boolean;
begin
  repeat
    Flag:= False;
    if Self.Count > 0 then begin
      for i:= Self.Count - 1 downto 0 do begin
        Flag:= Self.Items[i].FCounter > 0;
        if not Flag then begin
          Self.Delete(i);
          Flag:= True;
          Break;
        end;
        Flag:= False;
      end;
    end;
  until not Flag;
end;

procedure TPackRec.ChangeCounter(IncValue: Boolean);
var
  Value : Int16;
begin
  Value:= Counter;
  if IncValue then
    Value:= Value + 1
  else
    Value:= Value - 1;
  Counter:= Value;
end;

尝试更改Counter属性的值时遇到严重问题,Counter属性是唯一具有更改值的项目.ChangeCounter方法应该改变Counter的值,显然已经完成了,但是对于CheckForUnusedItems方法没有改变,我几乎尝试了所有东西,但似乎每个TPackList和TRecList都是常量.我给你看一些照片:

项目添加成功

删除了FRecList的项目

ChangeCounter方法更改了Counter的值

CheckForUnusedItems方法看不到任何更改

Counter属性将其值保持为常量

怎么了？对此有解释吗？我怎么解决呢？提前致谢.

Answer 1

默认的indexer属性TList返回容器内值的副本 ; 然后你调用ChangeCounter该副本,它会更改该副本的字段.容器内的原始项目没有变化.如果你想让它工作,你必须将它存储在本地,调用该本地的任何变异方法,然后将本地存储回容器,覆盖旧值.

这适用于除数组之外的任何容器,因为无法"通过引用返回",因此对返回值的进一步变异操作将反映在容器本身中.