Vim脚本中的"reduce"功能

Question

Vim脚本有一些非常基本的函数编程工具.

它有map()和filter(),但据我所知它缺乏一个reduce()功能." Reduce "将值集合减少为单个值.

有没有办法reduce()在Vim脚本中以某种方式创建或模拟它？是否可以在Vim脚本表达式中减少值列表而不编写显式循环？举个例子,有没有办法减少加法运算的前五个正整数,就像函数式语言课程一样？

在JavaScript中:

[1, 2, 3, 4, 5].reduce(function(x, y) { return x + y; });
15

在Clojure中:

(reduce + (range 1 (inc 5)))
15

在Haskell:

foldl (+) 0 [1..5]
15

在J:

+/>:i.5
15

在Vim脚本中:...？

Answer 1

为了将来的参考,以下是我对主题的变化,受到@MatthewStrawbridge链接的答案的启发.

原始示例问题的表达式:

eval(join(range(1, 5), '+'))

在同样的更通用的解决方案,使用Add(),其中a是range(1, 5):

eval(repeat('Add(',len(a)-1).a[0].','.join(a[1:],'),').')')

这构造了字符串"Add(Add(Add(Add(1,2),3),4),5)",然后eval是它.有趣!

最后,Reduce()它使用一个Funcref和一个列表,然后使用Vim的列表"destructuring"语法在循环中减少它[x, y; z].见:h :let-unpack.

function! Reduce(f, list)
  let [acc; tail] = a:list
  while !empty(tail)
    let [head; tail] = tail
    let acc = a:f(acc, head)
  endwhile
  return acc
endfunction

这就是它的用法:

:echo Reduce(function('Add'), range(1, 5))
15

Answer 2

我认为你应该构造一个字符串,然后执行它(我承认感觉有点笨重).help(:h E714)给出了这个例子:

:exe 'let sum = ' . join(nrlist, '+')

所以你的情况,在这里nrlist是[1, 2, 3, 4, 5],它会构建字符串let sum = 1+2+3+4+5,然后执行它.

或者,您可以编写自己的reduce函数,因为没有内置的函数.

编辑:

我发现了关于vim_use Google Group 的讨论(vim中的语言构建与emacs中的语言构建相比有多强大？,2010年1月25日)关于Vim中的函数编程,其中包括几个这样的reduce函数的实现.

第一个是Tom Link,如下:

function! Reduce(ffn, list) "{{{3
    if empty(a:list)
        return ''
    else
        let list = copy(a:list)
        let s:acc = remove(list, 0)
        let ffn = substitute(a:ffn, '\<v:acc\>', "s:acc", 'g')
        for val in list
            let s:acc = eval(substitute(ffn, '\<v:val\>', val, 'g'))
        endfor
        return s:acc
    endif
endf


echom Reduce("v:val + v:acc", [1, 2, 3, 4])
echom Reduce("v:val > v:acc ? v:val : v:acc", [1, 2, 3, 4])
echom Reduce("'v:val' < v:acc ? 'v:val' : v:acc", split("characters",
'\zs'))

第二个是Antony Scriven,如下:

fun Reduce(funcname, list)
    let F = function(a:funcname)
    let acc = a:list[0]
    for value in a:list[1:]
        let acc = F(acc, value)
    endfor
    return acc
endfun

fun Add(a,b)
    return a:a + a:b
endfun

fun Max(a,b)
    return a:a > a:b ? a:a : a:b
endfun

fun Min(a,b)
    return a:a < a:b ? a:a : a:b
endfun

let list = [1,2,3,4,5]
echo Reduce('Add', list)
echo Reduce('Max', list)
echo Reduce('Min', list)